viewing paste Unknown #664 | Text

Posted on the
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388
/*//----------------------------------------------------------------//
//----------------Scripted by Spera---------------------------------//
//------------------FinalStrikeRO-----------------------------------//
//--------------------Disguise Event NPC v2-------------------------//
/-------------------------------------------------------------------//*/
 
 
yuno_pre,33,95,2    script  Disguise CP     968,{
 
if (getgmlevel()<50)
{
    mes "^3399FF[Disguise CP]^000000";  
    mes "Sorry, you are not a GM!";
    close;
}
 
mes "^3399FF[Disguise CP]^000000";  
mes "Hello GameMaster!";
mes "What do you want to do?";
switch(select("Start Event:Stop Event:Set number of rounds[^E50000"+$guessrounds+"^000000]:Set prize^E50000 ["+getitemname($guessprize)+"]^000000 ^E50000 ["+ $guessprizecount + "]^000000:Nothing"))
{
    case 1: 
    {
        next;
        mes "^3399FF[Disguise CP]^000000";
        mes "Please confirm by typing START."; 
        input .@confirm$;          
        if (.@confirm$ == "START") 
        {
            donpcevent "guessAnnouncer::OnGMStart"; 
            close;
        }
        mes "Confirmation failed";
        close;
        break;
    }
    case 2:
    {
        next;
        mes "^3399FF[Disguise CP]^000000";
        mes "Please confirm by typing STOP."; 
        input .@confirm$;          
        if (.@confirm$ == "STOP") 
        {
            donpcevent "guessAnnouncer::OnGMStop";
            close;
        }
        mes "Confirmation failed";
        close;
        break;
        
    }
    
    case 3:
    {
        next; mes "^3399FF[Disguise CP]^000000";
        mes "Please type in the new number."; 
        input $guessrounds; 
        if ($guessrounds > 30) set $guessrounds, 30;
        else if ($guessrounds < 1) set $guessrounds, 1;
        close;
    }
    
    case 4:
    {
        next; mes "^3399FF[Disguise CP]^000000";
        mes "Please type in the new prize id."; 
        input .@guessprizeid; 
        if (getitemname(.@guessprizeid) == "null" || getitemname(.@guessprizeid) == "") {next; mes "^3399FF[Disguise CP]^000000"; mes "Error"; mes "This item does not exist in the database..."; close;}
        set $guessprize, .@guessprizeid;
        next; mes "^3399FF[Disguise CP]^000000";
        mes "Please type in the amount."; 
        input .@guessprizeamount;
        if (!.@guessprizeamount) set .@guessprizeamount,1 ;
        set $guessprizecount,.@guessprizeamount; 
        next; mes "^3399FF[Disguise CP]^000000";
        mes "Prize has been set to ^E50000 "+ getitemname($guessprize)+ "^000000 and the amount to ^E50000 " +$guessprizecount+"^000000";
        close;
    }
    
                    
    case 5:
    {
        next; mes "^3399FF[Disguise CP]^000000";
        mes "Good bye"; 
        close;
    }
 
}
 
 
}
 
 
 
 
 
 
 
 
ama_test,50,100,4   script  Disguise NPC        794,{
 
if (!$guessbegin)
{
    mes "^3399FF[Disguise NPC]^000000";
    mes "The event is going to start soon!";
    close;
}
end;
 
OnStart:
    set $guessbegin, 1;
    set .DisguiseWon, 0;
    if (!$DisguiseRound)
    {
        npctalk "Alright. Let's get it over with ~.~ ";
        sleep 4000;
        npctalk "But first I will explain to you how to play the game.";
        sleep 6000;
        npctalk "I am going to disguise into a random monster.";
        sleep 5000;
        npctalk "You have to guess the monster's name and shout it out.";
        sleep 5000;
        npctalk "Don't bother about the use of capital and small initial letters.";
        sleep 8000;
        npctalk "Now get ready.";
        sleep 5000;
    }
    else if ($DisguiseRound < $guessrounds-1)
    {
        npctalk "Get ready for the next round.";
        setnpctimer 0;
        sleep 8000;
    }
    else
    {   
        npctalk "Last round now!";
        sleep 2000;
        npctalk "Get ready.";
        sleep 6000;
    }
 
    do
    {
        set .@guessrepeat, 0;
        set $monster, 1000 + rand(1,950);
        for (set .@k, 0; .@k <getarraysize($Forbidden); set .@k, .@k+1)
        {
            if ($monster == $Forbidden[.@k]) 
            {
                set .@guessrepeat, 1;
                break;
            }
        }
    }
    while (.@guessrepeat);
    setnpctimer 0;
    initnpctimer;
    setnpcdisplay "Disguise NPC",$monster;
    set $MonsterName$, strmobinfo(1,$monster);
    defpattern 1, "([^:]+):.*\\s"+$MonsterName$+"(.*)", "winround";
    activatepset 1;
    npctalk "What's my name?";
    sleep 3000;
    npcwalkto 102,103;
    sleep 2000;
    npcwalkto 102,99;
    end;
    
    OnTimer10000:
        if (!.DisguiseWon)
        { 
            npctalk "Come on. What monster am I?";
            sleep 3000;
            npcwalkto 102,103;
            sleep 2000;
            npcwalkto 102,99;
            if (!$guessactive)  {disablenpc "guesswarp"; disablenpc "Disguise NPC"; end;}
        }
        end;
 
 
    OnTimer25000:
        if (!.DisguiseWon) 
        {
            npctalk "Nobody knows that monster?";
            sleep 3000;
            npcwalkto 102,103;
            sleep 2000;
            npcwalkto 102,99;
        }
        end;
 
    OnTimer35000:
        if (!.DisguiseWon) 
        {
            npctalk "You get 10 more seconds to guess my name.";
            sleep 3000;
            npcwalkto 102,103;
            sleep 2000;
            npcwalkto 102,99;
        }
        end;
 
    OnTimer45000:
        if (!.DisguiseWon)
        { 
            npctalk "Round is over.";
            if (!$guessactive)  {disablenpc "guesswarp"; disablenpc "Disguise NPC"; end;}
            set $DisguiseRound, $DisguiseRound + 1;
            sleep 3000;
            deletepset 1;
            npctalk $MonsterName$ + " would have been the correct answer.";
            sleep 5000;
            if ($DisguiseRound >= $guessrounds)
            {
                set $DisguiseRound, 0;
                sleep 3000;
                npctalk "Event is over now!";
                sleep 3500;
                npctalk "See ya guys";
                sleep 2000;
                emotion 12;
                sleep 1000;
                set $guessactive, 0;
                mapwarp "ama_test.gat","caspen.gat",181,228;
                setnpcdisplay "Disguise NPC",794;
                disablenpc "Disguise NPC";
                end;
            }
            goto OnStart;
        }
        end;
 
    winround:
        setnpctimer 0;
        deletepset 1;
        set .DisguiseWon, 1;
        set $DisguiseRound, $DisguiseRound + 1;
        npctalk strcharinfo(0) + " got my right name!",0;
        sleep2 3000;
        npctalk $MonsterName$ + " is the correct answer.";
        sleep2 3000;
        npctalk "Take this as a reward.";
        getitem $guessprize, $guessprizecount;
        if (!$guessactive)  {disablenpc "guesswarp"; disablenpc "Disguise NPC"; end;}
        if ($DisguiseRound >= $guessrounds)
            {
                set $DisguiseRound, 0;
                set $guessactive, 0;
                sleep 3000;
                npctalk "Event is over now!";
                sleep 3500;
                npctalk "See ya guys";
                sleep 2000;
                emotion 12;
                sleep 1000;
                mapwarp "ama_test.gat","caspen.gat",181,228;
                setnpcdisplay "Disguise NPC",794;
                disablenpc "Disguise NPC";
                end;
            }
        sleep 5000;
        goto OnStart;
        end;
 
    
 
}
 
//-----------------------------------------------------------------------------------
//-----------------------------------------------------------------------------------
 
-   script  guessAnnouncer  -1,{
 
 
OnGMStart:
    if ($guessactive) end;
    set $guessactive, 1;
    announce "A Gamemaster has started the Disguise Event",0;
    set $guessbegin, 0;
    sleep 3000;
    if (!$guessactive) end;
    announce "If you want to join, come to the main town, head downwards and enter the warp portal.",0;
    enablenpc "guesswarp";
    enablenpc "Disguise NPC";
    sleep 3000;
    announce "Number of Rounds: "+$guessrounds,0;
    sleep 2000;
    announce "Prize: "+ getitemname($guessprize) + " x " + $guessprizecount,0;
    sleep 2000;
    if (!$guessactive) {disablenpc "guesswarp"; disablenpc "Disguise NPC"; end;}
    announce "The portal is going to close in one minute.",0;  
    sleep 60000;
    if (!$guessactive) {disablenpc "guesswarp"; disablenpc "Disguise NPC"; end;}
    announce "The portal has been closed.",0;
    disablenpc "guesswarp";
    set $DisguiseRound, 0;
    sleep 5000;
    if (!$guessactive) {disablenpc "Disguise NPC"; end;}
    if(getmapusers("ama_test") == 0) 
    {
        disablenpc "Disguise NPC";
        set $guessactive, 1;
        end;
    }
 
    donpcevent "Disguise NPC::OnStart";
    end;
 
OnGMStop:
        if ($guessactive)
        {
            set $guessactive, 0;
            announce "A Gamemaster has stopped the Disguise Event",0;
            set $DisguiseRound, 0;
            mapwarp "ama_test.gat","caspen.gat",181,228;
            setnpcdisplay "Disguise NPC",794;
            disablenpc "Disguise NPC";
            disablenpc "guesswarp";
        }
        end;
 
 
OnClock0200:
OnClock0400:
OnClock0600:
OnClock0800:
OnClock1000:
OnClock1200:
OnClock1400:
OnClock1600:
OnClock1800:
OnClock2000:
OnClock2200:
OnClock0000:
    if ($guessactive) end;
    set $guessactive, 1;
    announce "The server is starting a Disguise Event now.",0;
    set $guessbegin, 0;
    sleep 3000;
    if (!$guessactive) end;
    announce "If you want to join, come to the main town, head downwards and enter the warp portal.",0;
    enablenpc "guesswarp";
    enablenpc "Disguise NPC";
    sleep 2000;
    announce "Prize: "+ getitemname($guessprize) + " x " + $guessprizecount,0;
    sleep 2000;
    if (!$guessactive)  {disablenpc "guesswarp"; disablenpc "Disguise NPC"; end;}
    announce "The portal is going to close in one minute.",0;  
    sleep 60000;
    if (!$guessactive)  {disablenpc "guesswarp"; disablenpc "Disguise NPC"; end;}
    announce "The portal has been closed.",0;
    disablenpc "guesswarp";
    sleep 5000;
    if (!$guessactive)  {disablenpc "Disguise NPC"; end;}
    announce "Next Event will start in 2 hours.",0;
    set $DisguiseRound, 0;
    if(getmapusers("poring_c01") == 0) 
    {
        disablenpc "Disguise NPC";
        set $guessactive, 0;
        end;
    }
 
    donpcevent "Disguise NPC::OnStart";
    end;
 
OnInit:
    disablenpc "Disguise NPC";
    disablenpc "guesswarp";
    set $guessactive, 0;
    setarray $Forbidden[0],1003,1006,1017,1021,1022,1027,1043,1136,1137,1168,1171,1172,1173,1181,1210,1217,1218,1223,1284,1324,1325,1326,1327,1328,1329,1330,1331,1332,1333,1334,1335,1336,1337,1338,1339,1340,1341,1342,1343,1344,1345,1346,1347,1348,1349,1350,1351,1352,1353,1354,1355,1356,1357,1358,1359,1360,1361,1362,1363,1407,1411,1414,1496,1501,1900;
 
}
 
//-----------------------------------------------------------------------------------
//--------------Warp Portal------------------------------------------------------
caspen,181,228,0    warp    guesswarp   2,2,ama_test,50,84  
//-----------------------------------------------------------------------------------
//------------------Map Flags--------------------------------------------------------
ama_test    mapflag nowarpto
ama_test    mapflag noskill
ama_test    mapflag nosave
ama_test    mapflag nomemo
ama_test    mapflag noteleport
ama_test    pvp off
//-----------------------------------------------------------------------------------
Viewed 719 times, submitted by Guest.