viewing paste Unknown #51081 | Athena

Posted on the
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72
prt_in,136,112,3        script  Pori Gatcha     506,{
        .@zeny = 300000;
        .@cashpoints = 30;
        .@item = 42092;
       
        // setarray .@box1, "chance", item id, amount...
        setarray .@box1, 1, 42088, 100;
        setarray .@box2, 10, 42088, 20, 14616, 2, 14619, 2, 12214, 5, 6635, 1, 6635, 2, 12103, 5, 6232, 1, 6228, 1, 12433, 8, 12412, 5;
        setarray .@box3, 20, 42088, 15, 6919, 5, 14616, 5, 22843, 5, 14617, 5, 12404, 5, 6380, 5, 6081, 5, 12122, 5;
        setarray .@box4, 30, 6081, 2, 6080, 2, 6380, 2, 42088, 20, 14616, 5, 14620, 5, 12430, 5, 12429, 5;
        setarray .@box5, 40, 22843, 2, 12404, 2, 12379, 2, 22843, 2, 12016, 5, 12431, 2, 12432, 2;
        setarray .@box6, 50, 6919, 2, 14616, 1, 14620, 1, 14617, 1, 14618, 1, 12214, 1, 14621, 1, 14619, 1;
        setarray .@box7, 60, 6919, 2, 12103, 2, 12429, 1, 12434, 1;
        setarray .@box8, 80, 12122, 3, 12016, 5;
        setarray .@box9, 100, 14524, 5;
       
        mes "What do you want to do?";
        next;
        switch(select("View item and rates", (.@item) ? "Use 1 x "+ getitemname(.@item):"", (.@zeny) ? "Use "+ F_InsertComma(.@zeny) +" Zeny":"", (.@cashpoints) ? "Use "+ F_InsertComma(.@cashpoints) +" Cashpoints":"")) {
        case 1: // view item rates
                mes "Item x Amount : Rate%";
                mes " "+ getitemname(.@box9[1]) +" x "+ .@box9[2] +" : default";
                for(.@i=8;.@i>0;.@i--)
                        for(.@j=1;.@j<getarraysize(getd(".@box"+.@i));.@j+=2)
                        mes " "+ getitemname(getd( ".@box"+.@i+"["+(.@j)+"]")) +" x "+ getd( ".@box"+.@i+"["+(.@j+1)+"]") +" : "+getd( ".@box"+.@i+"[0]")+"%";
                close;
               
        case 2: // use item
                if ( countitem(.@item) < 1 ) {
                        mes "Sorry, you need 1 x "+getitemname(.@item)+" to access my service";
                        close;
                }
                delitem .@item, 1;
                break;
               
        case 3: // use zeny
                if ( Zeny < .@zeny ) {
                        mes "Sorry, you need "+F_InsertComma(.@zeny)+" Zeny to access my service";
                        close;
                }
                Zeny -= .@zeny;
                break;
               
        case 4: // use cashpoints
                if ( #CASHPOINTS < .@cashpoints ) {
                        mes "Sorry, you need "+F_InsertComma(.@cashpoints)+" Cashpoints to access my service";
                        close;
                }
                #CASHPOINTS -= .@cashpoints;
                break;
        }
       
        for (.@i = 1; .@i<6; .@i++) {
                cutin "177_0"+.@i,4;
                sleep2 rand(100,200);
                cutin "",255;
        }
       
        .@r = rand(100); if (.@r <= 10) .@r = rand(100);
        while( .@r >= getd( ".@box"+.@boxnum+"[0]" ) ) .@boxnum++;
        .@arr_size = (getarraysize(getd(".@box"+.@boxnum))-1) / 2;
        if(.@arr_size > 1) .@rand_index = rand(1,.@arr_size); else .@rand_index = 1;
        getitem getd(".@box"+.@boxnum+"["+((.@rand_index*2)-1)+"]"), getd(".@box"+.@boxnum+"["+(.@rand_index*2)+"]");
        if ( .@boxnum == 1 || .@boxnum == 2 ) announce "Amazing! [ " +strcharinfo(0)+ " ] has and won "+getitemname(getd(".@box"+.@boxnum+"["+((.@rand_index*2)-1)+"]"))+" x "+getd(".@box"+.@boxnum+"["+(.@rand_index*2)+"]")+" from Pori Gacha!",bc_blue|bc_all;
        emotion 46,strcharinfo(0);
        mes "Congrats!";
        mes "You won :";
        mes "~ ^FF0000"+getitemname(getd(".@box"+.@boxnum+"["+((.@rand_index*2)-1)+"]"))+" x "+ getd(".@box"+.@boxnum+"["+(.@rand_index*2)+"]")+"^000000 !";
        close;
       
       
}
Viewed 157 times, submitted by pajodex.