//Nightmare toy factory

-	script	CelDead	HIDDEN_WARP_NPC,{
end;

function GetReward {
	if(!CelineCNT){
		dispbottom "You have defeated Celine! Return to Santa's assistant in the first floor to inform him!"; 
		CelineCNT = 1;
	}
	return;
}

OnCelineKilled:
	if( !getcharid(1) ){ //no party
		GetReward;
		end;
	}
	getmapxy .@Kmap$, .@Kx, .@Ky, 0;
	getpartymember(getcharid(1), 2);
	for(.@i = 0;.@i < $@partymembercount; ++.@i){
		if(attachrid($@partymemberaid[.@i])){
			getmapxy .@map$, .@x, .@y, 0;
			if(distance(.@Kx, .@Ky, .@x, .@y) <= 20 && .@Kmap$ == .@map$) //20 cells around killer
				GetReward;
		}
	}
	end;
}

xmas_dun01,132,123,4	script	Santa's Assistant#NToy	4_M_06,{
	.@a$ = "[Santa's Helper]";
	if (CelineCNT == 1) {
		mes .@a$;
		mes "Thank you for defeating Celine!";
		next;
		mes .@a$;
		mes "The other spirits didn't seem to leave, but we're hopeful that without her interference, they won't be much problem.";
		next;
		mes .@a$;
		mes "Mr. Claus asked me to give you this as thanks. Merry Christmas!";
		callfunc("Get_Rep", 3, 50);
		getitem 18844,1; //Santa Marin Balloon
		if(BaseLevel >= 70) getitem 667,5;
		if(BaseLevel >= 80) getitem 12354,5;
		if(BaseLevel >= 90) getitem 10900,3;
		CelineCNT = 2;
		close;
	}
	if (CelineCNT >= 2) {
		mes .@a$;
		mes "Thanks for your help again. Do you want to return to the second floor to help clear out the remaining spirits?";
		next;
		if(select("No thanks.:Yes.") == 1){
			mes .@a$;
			mes "Oh~ Okay.";
			close;
		}
		mes .@a$;
		if(isnight()){
			mes "Take care.";
			close2;
			warp "1@xm_d", 129, 126;
			end;
		}
		mes "Great! It's not night time yet, so the upper floor is its usual self. Come back during the night!";
		close;
	}
	mes .@a$;
	mes "Hello adventurer. Do you have some time to assist us?";
	next;
	if(select("Decline:Inquire") == 1){
		mes .@a$;
		mes "Well, be careful around here. Especially during the night...";
		close;
	}
	mes .@a$;
	mes "Recently, some toys in the second floor have sprung to life during the night, and rebelled against Mr. Claus. It seems some sinister spirits are haunting the area...";
	next;
	mes .@a$;
	mes "Mr. Claus has tried to deal with the spirits, but they won't leave. It seems that Celine, an old, abandoned puppet, might be the mastermind behind everything.";
	next;
	mes .@a$;
	mes "We're worried the haunting will delay our toy production, so we're looking for someone who could vanquish Celine. Could you help?";
	next;
	if(select("Decline:Agree to Help") == 1){
		mes .@a$;
		mes "I see... We'll keep looking for people, then.";
		close;
	}
	if(isnight()){
		mes .@a$;
		mes "Great, thanks a lot! I'll show you to the second floor if you're ready to go.";
		next;
		if(select("Cancel:I'm ready!") == 1){
			mes .@a$;
			mes "Talk to me again when you're ready";
			close;
		}
		mes .@a$;
		mes "Okay. If you bring people to help in the fight, please make sure you're all in the same party and near the person who lands the finishing strike on Celine. Otherwise, I won't know who helped and who to reward!";
		close2;
		warp "1@xm_d", 129, 126;
		end;
	}
	mes "Great! It's not night time yet, so the upper floor is its usual self. Come back during the night!";
	close;
}



//== Warps =================================
1@xm_d,129,130,0	warp	NightToy1	1,1,xmas_dun01,132,130
1@xm_d,129,79,0	warp	NightToy2	1,1,1@xm_d,129,72
1@xm_d,129,76,0	warp	NightToy3	1,1,1@xm_d,129,83
1@xm_d,179,130,0	warp	NightToy4	1,1,1@xm_d,188,130
1@xm_d,183,130,0	warp	NightToy5	1,1,1@xm_d,175,130
1@xm_d,129,179,0	warp	NightToy6	1,1,1@xm_d,129,189
1@xm_d,130,183,0	warp	NightToy7	1,1,1@xm_d,130,174
1@xm_d,79,130,0	warp	NightToy8	1,1,1@xm_d,72,130
1@xm_d,76,130,0	warp	NightToy9	1,1,1@xm_d,84,130
1@xm_d,107,208,0	warp	NightToy10	1,1,1@xm_d,97,208
1@xm_d,99,208,0	warp	NightToy11	1,1,1@xm_d,110,208
1@xm_d,152,208,0	warp	NightToy12	1,1,1@xm_d,163,208
1@xm_d,160,208,0	warp	NightToy13	1,1,1@xm_d,149,208


//== Spawns =================================
1@xm_d,0,0,0,0	monster	Antonio	2988,10,5000,0
1@xm_d,0,0,0,0	monster	Haunted Cookie	2989,20,5000,0
1@xm_d,0,0,0,0	monster	Haunted Cruiser	2990,20,5000,0
1@xm_d,0,0,0,0	monster	Haunted Myst Case	2991,20,5000,0
1@xm_d,0,0,0,0	monster	Snow Lude	2992,20,5000,0
1@xm_d,0,0,0,0	monster	Christmas Hylozoist	2993,15,5000,0
1@xm_d,0,0,0,0	monster	Lutian Marionette	2994,20,5000,0
1@xm_d,0,0,0,0	monster	Haunted Teddy Bear	2995,10,5000,0
1@xm_d,0,0,0,0	boss_monster	Celine Kimi	2996,1,5400000,1800000,"CelDead::OnCelineKilled"