//===== Hercules Script ======================================
//= Warper
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.4
//===== Description: =========================================
//= A complete - but very condensed - warper script.
//= Some coordinates written by Tekno-Kanix and ToastOfDoom.
//===== Additional Comments: =================================
//= 1.0 Initial script.
//= 1.1 Added missing duplicates and fixed coordinates.
//= 1.2 Added new episodes and simplified functions.
//= 1.3 Added Renewal checks and Instances menu.
//=     Aligned coordinates with @go.
//= 1.4 Added new Guild Dungeons.
//============================================================

-	script	Warper	-1,{
function Go; function Disp; function Pick; function Restrict;

// --------------------------------------------------
//	Main Menu:
// --------------------------------------------------

menu	"Last Warp ^777777["+lastwarp$+"]^000000",-,
	" ~ Towns",Towns, " ~ Dungeons",Dungeons, " ~ Special Areas",Special,

	if (lastwarp$ == "")
		message strcharinfo(0),"You haven't warped anywhere yet. '-' I can't send you to nothingness can I?";
	else
		warp lastwarp$,lastwarpx,lastwarpy;
	close;

// ------------------- Functions -------------------
// * Go("<map>",<x>,<y>);
//	~ Warps directly to a map.
//
// * Disp("<Menu Option>",<first option>,<last option>);
// * Pick("<map_prefix>"{,<index offset>});
//	~ Dynamic menu and map selection (auto-numbered).
//
// * Disp("<Option 1>:<Option 2>:<etc.>");
// * Pick("","<map1>","<map2>","<etc.>");
//	~ Manual menu and map selection (listed).
//
// * Restrict("<RE | Pre-RE>"{,<menu option numbers>});
//	~ Only allows map for Renewal or Pre-Renewal modes.
//     If menu option numbers are given, only those maps
//     will be restricted (i.e. not for "Go").
//
// Other notes:
//   ~ Array @c[] holds all (x,y) coordinates.
//   ~ Use @c[2] EXCEPT when maps begin dynamically
//	  at 0: use @c[0] and Pick() offset 1.
// --------------------------------------------------

function Go {
	warp getarg(0),getarg(1,0),getarg(2,0);
	getmapxy(lastwarp$,lastwarpx,lastwarpy,0);
	end;
}
function Disp {
	if (getargcount() < 3)
		set @menu$, getarg(0);
	else {
		set @menu$,"";
		for(set .@i,getarg(1); .@i<=getarg(2); set .@i,.@i+1)
			set @menu$, @menu$+getarg(0)+" "+.@i+":";
	}
	return;
}
function Pick {
	set .@warp_block,@warp_block;
	set @warp_block,0;
	if (getarg(0) == "") {
		set .@select, select(@menu$);
		set .@i, .@select;
		set .@map$, getarg(.@i);
	} else {
		set .@select, select(@menu$);
		set .@i, .@select-getarg(1,0);
		set .@map$, getarg(0)+((.@i<10)?"0":"")+.@i;
	}
	if (.@warp_block & (1<<.@select)) {
		message strcharinfo(0),"This map is not enabled in "+((checkre(0))?"":"Pre-")+"Renewal.";
		close;
	}
	warp .@map$,@c[.@i*2],@c[.@i*2+1];
	getmapxy(lastwarp$,lastwarpx,lastwarpy,0);
	deletearray @c[0],getarraysize(@c);
	end;
}
function Restrict {
	if ((getarg(0) == "RE" && !checkre(0)) || (getarg(0) == "Pre-RE" && checkre(0))) {
		if (getarg(1,0)) {
			set @warp_block,0;
			for(set .@i,1; .@i<getargcount(); set .@i,.@i+1)
				set @warp_block, @warp_block | (1<<getarg(.@i));
		} else {
			message strcharinfo(0),"This map is not enabled in "+((checkre(0))?"":"Pre-")+"Renewal.";
			close;
		}
	}
	return;
}

// --------------------------------------------------
	Towns:
// --------------------------------------------------
menu	"Prontera",T1, "Alberta",T2, "Aldebaran",T3, "Amatsu",T4, "Ayothaya",T5,
	"Brasilis",T6, "Comodo",T7, "Dewata",T8, "Eclage",T9, "Einbech",T10,
	"Einbroch",T11, "El Dicastes",T12, "Geffen",T13, "Gonryun",T14, "Hugel",T15,
	"Izlude",T16, "Jawaii",T17, "Lighthalzen",T18, "Louyang",T19, "Lutie",T20,
	"Malangdo",T21, "Malaya",T22, "Manuk",T23, "Midgarts Expedition Camp",T24,
	"Mora",T25, "Morroc",T26, "Moscovia",T27, "Nameless Island",T28,
	"Niflheim",T29, "Payon",T30, "Rachel",T31, "Splendide",T32, "Thor Camp",T33,
	"Umbala",T34, "Veins",T35, "Yuno",T36;

T1: Go("prontera",155,183);
T2: Go("alberta",117,44);
T3: Go("aldebaran",141,100);
T4: Go("amatsu",114,130);
T5: Go("ayothaya",208,166);
T6: Restrict("RE");
	Go("brasilis",196,217);
T7: Go("comodo",209,143);
T8: Restrict("RE");
	Go("dewata",200,180);
T9: Restrict("RE");
	Go("ecl_in01",48,53);
T10: Go("einbech",187,120);
T11: Go("einbroch",64,200);
T12: Restrict("RE");
	Go("dicastes01",198,187);
T13: Go("geffen",119,59);
T14: Go("gonryun",160,120);
T15: Go("hugel",96,145);
T16: Go("izlude",128,114);
T17: Go("jawaii",251,132);
T18: Go("lighthalzen",158,92);
T19: Go("louyang",217,100);
T20: Go("xmas",147,134);
T21: Restrict("RE");
	Go("malangdo",140,114);
T22: Restrict("RE");
	Go("malaya",212,206);
T23: Go("manuk",282,138);
T24: Go("mid_camp",210,288);
T25: Restrict("RE");
	Go("mora",55,146);
T26: Go("morocc",156,93);
T27: Go("moscovia",223,184);
T28: Go("nameless_n",256,215);
T29: Go("niflheim",202,174);
T30: Go("payon",179,100);
T31: Go("rachel",130,110);
T32: Go("splendide",201,147);
T33: Go("thor_camp",246,68);
T34: Go("umbala",97,153);
T35: Go("veins",216,123);
T36: Go("yuno",157,51);

// --------------------------------------------------
	Dungeons:
// --------------------------------------------------
menu	"Abyss Lakes",D1, "Amatsu Dungeon",D2, "Anthell",D3,
	"Ayothaya Dungeon",D4, "Beach Dungeon",D5, "Bio Labs",D6,
	"Brasilis Dungeon",D7, "Byalan Dungeon",D8, "Clock Tower",D9,
	"Coal Mines",D10, "Culvert",D11, "Cursed Abbey",D12, "Dewata Dungeon",D13,
	"Einbroch Dungeon",D14, "Gefenia",D15, "Geffen Dungeon",D16,
	"Glast Heim",D17, "Gonryun Dungeon",D18, "Hidden Dungeon",D19,
	"Ice Dungeon",D20, "Juperos",D21, "Kiel Dungeon",D22, "Louyang Dungeon",D23,
	"Magma Dungeon",D24, "Malangdo Dungeon",D25, "Moscovia Dungeon",D26,
	"Nidhogg's Dungeon",D27, "Odin Temple",D28, "Orc Dungeon",D29,
	"Payon Dungeon",D30, "Pyramids",D31, "Rachel Sanctuary",D32,
	"Scaraba Hole",D33, "Sphinx",D34, "Sunken Ship",D35, "Thanatos Tower",D36,
	"Thor Volcano",D37, "Toy Factory",D38, "Turtle Dungeon",D39, "Umbala Dungeon",D40;

D1: setarray @c[2],261,272,275,270,116,27;
	Disp("Abyss Lakes",1,3); Pick("abyss_");
D2: setarray @c[2],228,11,34,41,119,14;
	Disp("Amatsu Dungeon",1,3); Pick("ama_dun");
D3: setarray @c[2],35,262,168,170;
	Disp("Anthell",1,2); Pick("anthell");
D4: setarray @c[2],275,19,24,26;
	Disp("Ancient Shrine Maze:Inside Ancient Shrine"); Pick("ayo_dun");
D5: setarray @c[2],266,67,255,244,23,260;
	Disp("Beach Dungeon",1,3); Pick("","beach_dun","beach_dun2","beach_dun3");
D6: Restrict("RE",4);
	setarray @c[2],150,288,150,18,140,134,244,52;
	Disp("Bio Lab",1,4); Pick("lhz_dun");
D7: Restrict("RE");
	setarray @c[2],87,47,262,262;
	Disp("Brasilis Dungeon",1,2); Pick("bra_dun");
D8: Restrict("RE",6);
	setarray @c[0],168,168,253,252,236,204,32,63,26,27,141,187;
	Disp("Byalan Dungeon",1,6); Pick("iz_dun",1);
D9: setarray @c[2],199,159,148,283,65,147,56,155,297,25,127,169,277,178,268,74;
	Disp("Clock Tower 1:Clock Tower 2:Clock Tower 3:Clock Tower 4:Basement 1:Basement 2:Basement 3:Basement 4");
	Pick("","c_tower1","c_tower2","c_tower3","c_tower4","alde_dun01","alde_dun02","alde_dun03","alde_dun04");
D10: setarray @c[2],52,17,381,343,302,262;
	Disp("Coal Mines",1,3); Pick("mjo_dun");
D11: setarray @c[2],131,247,19,19,180,169,100,92;
	Disp("Culvert",1,4); Pick("","prt_sewb1","prt_sewb2","prt_sewb3","prt_sewb4");
D12: setarray @c[2],51,14,150,11,120,10;
	Disp("Cursed Abbey",1,3); Pick("abbey");
D13: Restrict("RE");
	setarray @c[2],285,160,299,29;
	Disp("Dewata Dungeon",1,2); Pick("dew_dun");
D14: setarray @c[2],22,14,292,290;
	Disp("Einbroch Dungeon",1,2); Pick("ein_dun");
D15: setarray @c[2],40,103,203,34,266,168,130,272;
	Disp("Gefenia",1,4); Pick("gefenia",0);
D16: setarray @c[0],104,99,115,236,106,132,203,200;
	Disp("Geffen Dungeon",1,4); Pick("gef_dun",1);
D17: setarray @c[2],370,304,199,29,104,25,150,15,157,287,147,15,258,255,108,291,171,283,68,277,156,7,12,7,133,271,224,274,14,70,150,14;
	Disp("Entrance:Castle 1:Castle 2:Chivalry 1:Chivalry 2:Churchyard:Culvert 1:Culvert 2:Culvert 3:Culvert 4:St. Abbey:Staircase Dungeon:Underground Cave 1:Underground Cave 2:Underground Prison 1:Underground Prison 2");
	Pick("","glast_01","gl_cas01","gl_cas02","gl_knt01","gl_knt02","gl_chyard","gl_sew01","gl_sew02","gl_sew03","gl_sew04","gl_church","gl_step","gl_dun01","gl_dun02","gl_prison","gl_prison1");
D18: setarray @c[2],153,53,28,113,68,16;
	Disp("Gonryun Dungeon",1,3); Pick("gon_dun");
D19: setarray @c[2],176,7,93,20,23,8;
	Disp("Hidden Dungeon",1,3); Pick("prt_maze");
D20: setarray @c[2],157,14,151,155,149,22,33,158;
	Disp("Ice Dungeon",1,4); Pick("ice_dun");
D21: setarray @c[2],140,51,53,247,37,63,150,285;
	Disp("Entrance:Juperos 1:Juperos 2:Core");
	Pick("","jupe_cave","juperos_01","juperos_02","jupe_core");
D22: setarray @c[2],28,226,41,198;
	Disp("Kiel Dungeon",1,2); Pick("kh_dun");
D23: setarray @c[2],218,196,282,20,165,38;
	Disp("The Royal Tomb:Inside the Royal Tomb:Suei Long Gon"); Pick("lou_dun");
D24: setarray @c[2],126,68,47,30;
	Disp("Magma Dungeon",1,2); Pick("mag_dun");
D25: Restrict("RE");
	setarray @c[2],33,230;
	Disp("Malangdo Dungeon",1,1); Pick("mal_dun");
D26: setarray @c[2],189,48,165,30,32,135;
	Disp("Moscovia Dungeon",1,3); Pick("mosk_dun");
D27: setarray @c[2],61,239,60,271;
	Disp("Nidhogg's Dungeon",1,2); Pick("nyd_dun");
D28: setarray @c[2],298,167,224,149,266,280;
	Disp("Odin Temple",1,3); Pick("odin_tem");
D29: setarray @c[2],32,170,21,185;
	Disp("Orc Dungeon",1,2); Pick("orcsdun");
D30: setarray @c[0],21,183,19,33,19,63,155,159,201,204;
	Disp("Payon Dungeon",1,5); Pick("pay_dun",1);
D31: setarray @c[2],192,9,10,192,100,92,181,11,94,96,192,8;
	Disp("Pyramids 1:Pyramids 2:Pyramids 3:Pyramids 4:Basement 1:Basement 2"); Pick("moc_pryd");
D32: setarray @c[2],140,11,32,21,4,149,204,218,150,9;
	Disp("Rachel Sanctuary",1,5); Pick("ra_san");
D33: Restrict("RE");
	setarray @c[2],364,44,101,141;
	Disp("Scaraba Hole",1,2); Pick("dic_dun");
D34: setarray @c[2],288,9,149,81,210,54,10,222,100,99;
	Disp("Sphinx",1,5); Pick("","in_sphinx1","in_sphinx2","in_sphinx3","in_sphinx4","in_sphinx5");
D35: setarray @c[2],69,24,102,27;
	Disp("Sunken Ship",1,2); Pick("treasure");
D36: setarray @c[2],150,39,150,136,220,158,59,143,62,11,89,221,35,166,93,148,29,107,159,138,19,20,130,52;
	Disp("Thanatos Tower",1,12); Pick("tha_t");
D37: setarray @c[2],21,228,75,205,34,272;
	Disp("Thor Volcano",1,3); Pick("thor_v");
D38: setarray @c[2],205,15,129,133;
	Disp("Toy Factory",1,2); Pick("xmas_dun");
D39: setarray @c[2],154,49,148,261,132,189,100,192;
	Disp("Entrance:Turtle Dungeon 1:Turtle Dungeon 2:Turtle Dungeon 3"); Pick("tur_dun");
D40: Restrict("Pre-RE",1,2);
	setarray @c[2],42,31,48,30,204,78;
	Disp("Carpenter's Shop in the Tree:Passage to a Foreign World:Hvergermil's Fountain");
	Pick("","um_dun01","um_dun02","yggdrasil01");


// --------------------------------------------------
	Special:
// --------------------------------------------------
menu	"Auction Hall",S1, "Battlegrounds",S2, "Casino",S3, "Eden Group Headquarters",S4,
	"Gonryun Arena",S5, "Izlude Arena",S6, "Monster Race Arena",S7, "Turbo Track",S8;

S1: Go("auction_01",22,68);
S2: Go("bat_room",154,150);
S3: Go("cmd_in02",179,129);
S4: Restrict("RE");
	Go("moc_para01",31,14);
S5: Go("gon_test",48,10);
S6: Go("arena_room",100,88);
S7: Go("p_track01",62,41);
S8: Go("turbo_room",99,114);
}

// --------------------------------------------------
//	Duplicates:
// --------------------------------------------------
alb2trea,57,70,6	duplicate(Warper)	Warper#tre	4_F_SHALOSH
alberta,119,68,4	duplicate(Warper)	Warper#alb	4_F_SHALOSH
aldebaran,145,118,4	duplicate(Warper)	Warper#alde	4_F_SHALOSH
amatsu,123,146,4	duplicate(Warper)	Warper#ama	4_F_SHALOSH
ayothaya,209,169,6	duplicate(Warper)	Warper#ayo	4_F_SHALOSH
comodo,194,158,4	duplicate(Warper)	Warper#com	4_F_SHALOSH
einbech,204,128,6	duplicate(Warper)	Warper#einbe	4_F_SHALOSH
einbroch,69,202,4	duplicate(Warper)	Warper#einbr	4_F_SHALOSH
gef_fild10,71,339,4	duplicate(Warper)	Warper#orc	4_F_SHALOSH
geffen,124,72,4	duplicate(Warper)	Warper#gef	4_F_SHALOSH
glast_01,372,308,4	duplicate(Warper)	Warper#glh	4_F_SHALOSH
gonryun,164,120,4	duplicate(Warper)	Warper#gon	4_F_SHALOSH
hugel,77,163,4	duplicate(Warper)	Warper#hug	4_F_SHALOSH
izlu2dun,110,92,4	duplicate(Warper)	Warper#izd	4_F_SHALOSH
izlude,125,148,4	duplicate(Warper)	Warper#izl	4_F_SHALOSH
jawaii,253,138,4	duplicate(Warper)	Warper#jaw	4_F_SHALOSH
lighthalzen,162,102,4	duplicate(Warper)	Warper#lhz	4_F_SHALOSH
louyang,208,103,6	duplicate(Warper)	Warper#lou	4_F_SHALOSH
manuk,274,146,6	duplicate(Warper)	Warper#man	4_F_SHALOSH
mid_camp,216,288,4	duplicate(Warper)	Warper#mid	4_F_SHALOSH
mjolnir_02,85,364,4	duplicate(Warper)	Warper#mjo	4_F_SHALOSH
moc_ruins,64,164,4	duplicate(Warper)	Warper#moc	4_F_SHALOSH
morocc,159,97,4	duplicate(Warper)	Warper#mor	4_F_SHALOSH
moscovia,229,191,4	duplicate(Warper)	Warper#mos	4_F_SHALOSH
nameless_n,259,213,4	duplicate(Warper)	Warper#nam	4_F_SHALOSH
niflheim,205,179,4	duplicate(Warper)	Warper#nif	4_F_SHALOSH
pay_arche,42,134,4	duplicate(Warper)	Warper#arc	4_F_SHALOSH
payon,156,96,4	duplicate(Warper)	Warper#pay	4_F_SHALOSH
prontera,162,190,4	duplicate(Warper)	Warper#prt	4_F_SHALOSH
prontera,198,159,4	duplicate(Warper)	Warper#novprt	4_F_SHALOSH
prt_fild05,279,223,6	duplicate(Warper)	Warper#cul	4_F_SHALOSH
rachel,135,116,4	duplicate(Warper)	Warper#rac	4_F_SHALOSH
splendide,205,153,4	duplicate(Warper)	Warper#spl	4_F_SHALOSH
umbala,106,150,3	duplicate(Warper)	Warper#umb	4_F_SHALOSH
veins,214,123,4	duplicate(Warper)	Warper#ve	4_F_SHALOSH
xmas,150,134,6	duplicate(Warper)	Warper#xmas	4_F_SHALOSH
yuno,161,189,4	duplicate(Warper)	Warper#yuno	4_F_SHALOSH

// --------------------------------------------------
//	Duplicates (Renewal):
// --------------------------------------------------
brasilis,200,224,4	duplicate(Warper)	Warper#bra	4_F_SHALOSH
dewata,204,186,6	duplicate(Warper)	Warper#dew	4_F_SHALOSH
dicastes01,194,194,6	duplicate(Warper)	Warper#dic	4_F_SHALOSH
ecl_in01,51,60,4	duplicate(Warper)	Warper#ecl	4_F_SHALOSH
malangdo,134,117,6	duplicate(Warper)	Warper#mal	4_F_SHALOSH
malaya,210,205,4	duplicate(Warper)	Warper#ma	4_F_SHALOSH
mora,57,152,4	duplicate(Warper)	Warper#mora	4_F_SHALOSH