// Mapflags
1@brap	mapflag	nomemo
1@brap	mapflag	nosave	SavePoint
1@brap	mapflag	nopenalty
bra_gu1	mapflag	nomemo
bra_gu1	mapflag	nosave	SavePoint
bra_gu1	mapflag	nopenalty
bra_gu2	mapflag	nomemo
bra_gu2	mapflag	nosave	SavePoint
bra_gu2	mapflag	nopenalty
bra_gu3	mapflag	nomemo
bra_gu3	mapflag	nosave	SavePoint
bra_gu3	mapflag	nopenalty
bra_pub	mapflag	nomemo
bra_pub	mapflag	nosave	SavePoint
bra_pub	mapflag	nopenalty
bra_lob	mapflag	nomemo
bra_lob	mapflag	nobranch
bra_lob	mapflag	noteleport
bra_lob	mapflag	nopenalty

///////////////////////////////////////////////////////////////////////////
// NPCs

prontera,168,120,3	script	Boy#brap	4_M_KID1,{
	set bran_room,0;
	set .@pcname$,strcharinfo(0);
	mes "[Boy]";
	mes "Hey, shhht, you look strong, I have something to tell you.";
	next;
	mes "^0000AAThe boy unfolds a small piece of paper and begins to read out loud.^000000";
	next;
	mes "[Boy]";
	mes "'Come to Izlude ^0000BB117,96^000000 if you dare. The Moonlight Snatchers.'";
	next;
	mes "["+.@pcname$+"]";
	mes "Moonlight Snatcher? Never heard of them. What's it about?";
	next;
	mes "[Boy]";
	mes "I wouldn't know, I do not belong to them. They just paid me for speaking to people here in Prontera who look strong.";
	next;
	mes "["+.@pcname$+"]";
	mes "Oh well. Might as well check it out.";
	close;
}

bra_lob,101,50,0	script	#bra_lob01	WARPNPC,1,1,{
	if (olsavmap$ != "") {
		savepoint olsavmap$,olsavx,olsavy;
		set olsavmap$,"";
		olsavx = 0;
		olsavy = 0;
	}
	warp "izlude",122,96;
	end;
}

izlude,117,96,5	script	Shady Guy#bra_lob	4_M_ROGUE,6,6,{
	if (bran_room == 1) {
		mes "[Shady Guy]";
		mes "I hope none of those guards followed you.";
		mes "Well anyway, interested in some ... fun?";
		next;
		if (select("Sure, tell me!:Ehh... I've seen nothing...") == 2) {
			mes "[Shady Guy]";
			mes "...";
			close;
		}
		mes "[Shady Guy]";
		mes "Great. So you know those Bloody Branches, right? Ever wanted to be able to break some without other people complaining or interfering?";
		next;
		mes "[Shady Guy]";
		mes "Then follow me.";
		next;
		if (select("Alright.:Not now, I'm busy.") == 2) {
			mes "[Shady Guy]";
			mes "Not my problem.";
			close;
		}
		mes "The man leads you outside of Izlude to some kind of cave.";
		next;
		set bran_room,2;
		set olsavmap$,getsavepoint(0);
		olsavx = getsavepoint(1);
		olsavy = getsavepoint(2);
		savepoint "bra_lob",60,100;
		warp "bra_lob",99,57;
	} else if (bran_room > 1) {
		mes "[Shady Guy]";
		mes "Want to go to the cave?";
		next;
		if (select("Lead me there!:Not now.") == 2) {
			mes "[Shady Guy]";
			mes "Alright, it's up to you.";
			close;
		}
		set olsavmap$,getsavepoint(0);
		olsavx = getsavepoint(1);
		olsavy = getsavepoint(2);
		savepoint "bra_lob",60,100;
		warp "bra_lob",99,57;
	}
	end;
	
OnTouch:
	if (bran_room == 0) {
		npctalk "Hey ... psst! Over here!";
		set bran_room,1;
	}
	end;
}

bra_lob,95,60,5	script	Shady Guy#bra_lob2	4_M_ROGUE,{
	emotion e_gg;
	mes "[Shady Guy]";
	mes "This is the secret underground cave of the Moonlight Snatcher gang. Here you can book your own private room to break Bloody Branches or Dead Branches for a small fee...!";
	next;
	mes "[Shady Guy]";
	mes "Just talk to that overly polite guy up there.";
	next;
	mes "[Shady Guy]";
	mes "Uh.. I hope you don't mind that if you die in one of the rooms, you will actually lose some experience, except for the guild rooms and the public room, which is to the right.";
	close;
}

bra_lob,102,74,3	script	Moonlight Snatcher#1	1_M_SIGNMONK,{
	mes "[Moonlight Snatcher]";
	mes "I go here at least two times a week. That's probably why I'm broke all the time ...";
	next;
	mes "[Moonlight Snatcher]";
	mes "If you want to book a room, just talk to that 'Personnel' guy over there.";
	mes "You can only book one room at a time, but you can book as many rooms each day as you want.";
	next;
	mes "[Moonlight Snatcher]";
	mes "If you want to cancel a reservation, just talk to the respective personnel. You won't be refunded for the remaining minutes, though!";
	next;
	mes "[Moonlight Snatcher]";
	mes "If you booked a guild room and don't need it anymore, but there's still some time remaining, please cancel the reservation, so other guilds also have a chance at getting a room!";
	close;
}

bra_lob,110,115,3	script	Moonlight Snatcher#2	4_F_SITDOWN,{
	mes "[Moonlight Snatcher]";
	mes "Phew, I'm tired. I don't have any more Bloody Branches.";
	next;
	mes "[Moonlight Snatcher]";
	mes "I heard you can only get those branches from special events ...";
	close;
}

bra_lob,87,113,1	script	Intruder#bra3	4_M_JOB_WIZARD,{
	mes "[Suspicious Man]";
	mes "Hey! Shhht. You're not one of them either, are you?";
	next;
	mes "[Suspicious Man]";
	mes "I followed one of them down here, I think I found out how this works.";
	next;
	mes "[Suspicious Man]";
	mes "They drug you and then connect you to some kind of network device, so you see a virtual environment. Your brain will be in some kind of dream state during this time.";
	next;
	emotion e_bzz;
	mes "[Suspicious Man]";
	mes "I would never trust those thieves!!";
	close;
}

bra_lob,95,139,5	shop	Fence#bra4	1_M_SIGNMCNT,1750:2,1751:6,13200:2,13201:30,501:100,502:400,503:1100,504:2400,506:100,645:1600,656:3000,601:120,602:600,611:80,610:8000

bra_lob,106,135,3	script	Trustee#bra4	4_F_ROGUE,{
	mes "[Trustee]";
	mes "Give me your stuff!";
	mes "...";
	mes "Haha, no, I'm not trying to rob you!";
	next;
	mes "[Trustee]";
	mes "I manage the local storage here. If you're overweight or need anything from your storage, just tell me. I'll make you a good price, teehee~!";
	next;
	if (select("Open Storage (^DD0000120z^000000):No need for that.") == 2) {
		mes "[Trustee]";
		mes "Come back anytime!";
		close;
	}
	if (Zeny < 120) {
		mes "[Trustee]";
		mes "Aww, you don't even have 120z!";
		mes "Sorry, but no zeny, no business!";
		close;
	}
	Zeny = Zeny-120;
	mes "[Trustee]";
	mes "Thank you! Here you go. Take your time!";
	openstorage;
	close;
}

bra_lob,94,136,7	script	Forger#bra45	1_M_SMITH,{
	set .@repairprice,5800;
	mes "[Forger]";
	mes "Hey there!";
	mes "Got a problem with your equipment? If you give it to me, it'll be almost as new...";
	next;
	switch(select("Actually, I do have some items...:Can you also enhance my equipment?:Nah.")) {
	case 1:
		set .@checkitem,1;
		while (1) {
			if (getbrokenid(.@checkitem) == 0) {
				break;
			}
			set .@checkitem,.@checkitem+1;
		}
		set .@checkitem,.@checkitem-1;
		if (!.@checkitem) {
			mes "[Forger]";
			mes "Oh wow, this is incredible!";
			mes "You must take very good care of your things. None of your items are damaged!";
			close;
		}
		mes "[Forger]";
		mes "Hmm... Let's see...";
		mes "Out of all your items," + .@checkitem + " are damaged.";
		mes "Would you like me to repair them?";
		next;
		set .@totalcost,.@repairprice*.@checkitem;
		mes "[Forger]";
		mes "Each repair costs " + .@repairprice + " Zeny. So to repair all your damaged items would cost " + .@totalcost + " Zeny! It's dirt-cheap, right?";
		next;
		switch(select("Uh.. Yes:Too expensive!")) {
		case 1:
			if (Zeny < .@totalcost) {
				mes "[Forger]";
				mes "Whoa whoa...";
				mes "Check your wallet before you receive the repair bill! You don't have enough Zeny. No Zeny, no business!";
				close;
			}
			set .@checkitem2,1;
			while (1) {
				if (getbrokenid(.@checkitem2) == 0) {
					break;
				}
				set .@checkitem2,.@checkitem2+1;
			}
			set .@checkitem2,.@checkitem2-1;
			if (.@checkitem == .@checkitem2) {
				Zeny = Zeny-.@totalcost;
				while (.@checkitem) {
					repair(.@checkitem);
					set .@checkitem,.@checkitem-1;
				}
				mes "[Forger]";
				mes "Okay! All done. Now, try to be a little more careful. Items have lives too you know.";
				close;
			}
			else {
				mes "[Forger]";
				mes "Mmm? Something's wrong. Wait... Equip the items you need to repair and then come back to me.";
				close;
			}
			break;
		case 2:
			mes "[Forger]";
			mes "Pah! You won't find anyone cheaper than me! Also, it's no skin off my nose, but it's not good to leave items damaged!";
			close;
			break;
		}
		break;
	case 2:
		mes "[Forger]";
		mes "Hehe.";
		emotion e_gg;
		next;
		mes "[Forger]";
		mes "Dream on.";
		close;
		break;
	case 3:
		mes "[Forger]";
		mes "Hohoho... you don't trust me, eh. Well, as you wish. Not my problem.";
		close;
		break;
	}
}

bra_lob,81,102,4	script	Pharmacist#bra5	4_F_ALCHE,{
	mes "[Pharmacist]";
	mes "I tend your wounds...";
	mes "... of course only if you want me to!";
	mes "How about it?";
	next;
	switch (select("Heal me (^DD000050z^000000):Full Recharge! (HP & SP) (^E000001800z^000000):No need for that.")) {
	case 1:
		if (Zeny < 50) {
			mes "[Pharmacist]";
			mes "Ha, that must be a joke.";
			mes "No zeny, no business!";
			close;
		}
		Zeny = Zeny-50;
		mes "[Pharmacist]";
		mes "Alright. Here we go!";
		percentheal 100,0;
		specialeffect2 325;
		break;
	case 2:
		if (Zeny < 1800) {
			mes "[Pharmacist]";
			mes "Ha, that must be a joke.";
			mes "No zeny, no business!";
			close;
		}
		Zeny = Zeny-1800;
		mes "[Pharmacist]";
		mes "Alright. Here we go!";
		percentheal 100,100;
		specialeffect2 325;
		break;
	case 3:
		mes "[Pharmacist]";
		mes "You'll come back sooner or later!";
		break;
	}
	close;
}

bra_lob,103,105,1	script	Moonlight Snatcher#6	2_M_THIEFMASTER,{
	mes "[Moonlight Snatcher]";
	mes "They won't let me in, saying I'm too young. Pah ... I'm stronger than all of them!";
	close;
}

bra_lob,99,98,0	script	Entrance#bra1	2_M_THIEFMASTER,{
	set .@pname$,strcharinfo(0);
	set .@guid,getcharid(2);
	dispbottom "Name: " + instance_npcname(has_instance2("1@brap"));
	if ((has_instance2("1@brap") >= 0) && (has_instance2("1@brap") != "0")) {
		set .@party_id,getcharid(1);
		if (.@party_id == 0) {
			dispbottom "Error! Player is currently not in a party!";
			end;
		}
		getpartymember(.@party_id);
		set .@partymembercount,$@partymembercount;
		if (compare("BB solo",instance_npcname(has_instance2("1@brap")))) {
			if ((getcharid(0) != getpartyleader(.@party_id,2)) || (.@partymembercount != 1)) {
				dispbottom "Error! Only the party leader can enter the solo room with nobody else in the party.";
				end;
			}
		}
		if ((.@guid != 0) && ((.@guid == $bbguild[0]) || (.@guid == $bbguild[1]) || (.@guid == $bbguild[2]))) {
			mes "You have currently booked a guild room as well as a "+(compare("BB solo",instance_npcname(has_instance2("1@brap")))?"solo":"party")+" room, which one do you want to enter?";
			if (select("Guild room:"+(compare("BB solo",instance_npcname(has_instance2("1@brap")))?"Solo":"Party")+" room") == 1) goto GuildRoom;
		}
		set .@pname$,strcharinfo(0);
		message .@pname$,.@pname$+" : I feel a bit dizzy ...";
		sleep2 500;
		switch (rand(4)) {
		case 0:
			warp "1@brap",50,10;
			break;
		case 1:
			warp "1@brap",10,50;
			break;
		case 2:
			warp "1@brap",50,89;
			break;
		case 3:
			warp "1@brap",89,50;
			break;
		}
	} else if ((.@guid != 0) && ((.@guid == $bbguild[0]) || (.@guid == $bbguild[1]) || (.@guid == $bbguild[2]))) {
GuildRoom:
		set .@pname$,strcharinfo(0);
		message .@pname$,.@pname$+" : I feel a bit dizzy ...";
		sleep2 500;	
		if (.@guid == $bbguild[0])
			set .@gnui,1;
		else if (.@guid == $bbguild[1])
			set .@gnui,2;
		else if (.@guid == $bbguild[2])
			set .@gnui,3;
		switch (rand(4)) {
		case 0:
			warp "bra_gu"+.@gnui,50,10;
			break;
		case 1:
			warp "bra_gu"+.@gnui,10,50;
			break;
		case 2:
			warp "bra_gu"+.@gnui,50,89;
			break;
		case 3:
			warp "bra_gu"+.@gnui,89,50;
			break;
		}
	} else {
		message .@pname$,.@pname$+" : There are cables connected to that tree. Weird ...";
	}
	end;
}

1@brap,50,6,0	warp	brap_01	1,1,bra_lob,99,93
1@brap,6,50,0	warp	brap_02	1,1,bra_lob,99,93
1@brap,50,93,0	warp	brap_03	1,1,bra_lob,99,93
1@brap,93,50,0	warp	brap_04	1,1,bra_lob,99,93

bra_pub,40,37,0	warp	brap_06	1,1,bra_lob,144,98
bra_pub,32,206,0	warp	brap_07	1,1,bra_lob,144,98
bra_pub,203,207,0	warp	brap_08	1,1,bra_lob,144,98
bra_pub,191,40,0	warp	brap_09	1,1,bra_lob,144,98

//bra_lob,151,99,0	warp	bra_05	1,1,bra_pub,50,50

bra_lob,140,105,4	script	Moonlight Snatcher#7	4_M_JOB_ASSASSIN,{
	emotion e_gg;
	mes "[Moonlight Snatcher]";
	mes "I prefer the public map over the two private ones. Why? Well, you get to snatch a few MVPs from other players.";
	close;
}

bra_lob,151,99,0	script	Machine#bra_05	4_BOARD3,{
	set .@pname$,strcharinfo(0);
	if (bran_room < 3) {
		message .@pname$,.@pname$+" : There's a sign on that machine which says that I should insert some zeny.";
		set bran_room,3;
	} else if (bran_room == 3) {
		if (BaseLevel < 77) {
			if (Upper)
				set .@zeny,500;
			else
				set .@zeny,0;
		} else if (BaseLevel >= 97) {
			set .@zeny,500+Upper*1000;
		} else {
			set .@zeny,25*(BaseLevel-76)*(1+Upper)+Upper*500;
		}
		mes "[Public BB Room Access]";
		if (.@zeny) {
			mes "Please insert "+.@zeny+"z and then stick your hand into this opening.";
			next;
			if (select("Let's do this!:Not now.") == 2) close;
			if (Zeny < .@zeny) {
				mes "Error! Not enough zeny!";
				close;
			}
			Zeny = Zeny-.@zeny;
		} else {
			mes "You may enter for free. Please stick your hand into this opening!";
			next;
			if (select("Let's do this!:Not now.") == 2) close;
		}
		message .@pname$,.@pname$+" : I feel a bit dizzy ...";
		sleep2 500;
		switch (rand(4)) {
		case 0:
			warp "bra_pub",43,40;
			break;
		case 1:
			warp "bra_pub",35,203;
			break;
		case 2:
			warp "bra_pub",200,204;
			break;
		case 3:
			warp "bra_pub",188,43;
			break;
		}
	}
	end;
}

bra_lob,96,95,5	script	Instance Personnel#bra1	4_M_ORIENT02,{
	set .@party_id,getcharid(1);
	set .@ins_mas,getpartyleader(.@party_id,2);
	set .@p_name$,getpartyname(.@party_id);
	set .@p_reader$,strcharinfo(0);
	
	getpartymember(.@party_id);
	set .@partymembercount,$@partymembercount;
	copyarray .@partymembername$[0],$@partymembername$[0],.@partymembercount;

	if (has_instance2("1@brap") >= 0) {
		if (.@ins_mas != getcharid(0)) {
			mes "[Instance Room Personnel]";
			mes "You have already booked a room. Please ask your party leader to cancel the reservation or leave your party.";
			close;
		}
		mes "[Instance Room Personnel]";
		mes "Do you want to cancel your current reservation? Keep in mind that you won't get a refund for the remaining minutes!";
		next;
		if (select("No:Yes") == 2) {
			if (has_instance2("1@brap") != "") {
				set .@instance,has_instance("1@brap");
				instance_destroy(.@instance);
				mes "[Instance Room Personnel]";
				mes "Your reservation with the ID "+.@instance+" has been successfully canceled!";
				mes "You can now book a new room.";
			} else {
				mes "[Instance Room Personnel]";
				mes "There was an error when trying to delete the instance, please try again!";
			}
		} else {
			mes "[Instance Room Personnel]";
			mes "Alright then, I hope you have a good time!";
		}
		close;
	}
	
	mes "[Instance Room Personnel]";
	mes "Good day! May I book a room for you only or your whole party?";
	next;
	switch(select("A solo room, please.:A party room, please.:I want to enter the public room!:I want to book a room for my guild.:I don't want to book a room.")) {
	case 1:
		set .@roomtype$,"solo";
		break;
	case 2:
		set .@roomtype$,"party";
		break;
	case 3:
		mes "[Instance Room Personnel]";
		mes "In order to enter the virtual public room, please go east!";
		close;
		break;
	case 4:
		mes "[Instance Room Personnel]";
		mes "Then please talk to my college over there, he will assist you with renting guild rooms!";
		close;
		break;
	case 5:
		mes "[Instance Room Personnel]";
		mes "Have a nice day then!";
		close;
		break;
	}
	
	if (compare("solo",.@roomtype$)) {
		if ((.@partymembercount != 1) || (.@ins_mas != getcharid(0))) {
			mes "[Instance Room Personnel]";
			mes "In order to book a solo room, you need to be a party leader with no other members in the party.";
			mes "You can create a party with: /organize Party_Name";
			close;
		}
	} else if (compare("party",.@roomtype$)) {
		if ((.@partymembercount < 2) || (.@ins_mas != getcharid(0))) {
			mes "[Instance Room Personnel]";
			mes "In order to book a party room, you need to be a party leader with at least one other member in your party.";
			mes "You can create a party with: /organize Party_Name";
			close;
		}
	}
	
	mes "[Instance Room Personnel]";
	mes "For how many minutes do you want to book the "+.@roomtype$+" room?";
	next;
	switch (select("10 minutes (^00DD00"+(compare("solo",.@roomtype$)?"100":"500")+"z^000000):60 minutes (^0000DD"+(compare("solo",.@roomtype$)?"1000":"5000")+"z^000000):120 minutes (^DDDD00"+(compare("solo",.@roomtype$)?"1800":"9000")+"z^000000):180 minutes (^DD0000"+(compare("solo",.@roomtype$)?"2500":"13000")+"z^000000)")) {
	case 1:
		set .@timeout,600;
		set .@zeny,(compare("solo",.@roomtype$)?100:500);
		break;
	case 2:
		set .@timeout,3600;
		set .@zeny,(compare("solo",.@roomtype$)?1000:5000);
		break;
	case 3:
		set .@timeout,7200;
		set .@zeny,(compare("solo",.@roomtype$)?1800:9000);
		break;
	case 4:
		set .@timeout,10800;
		set .@zeny,(compare("solo",.@roomtype$)?2500:13000);
		break;
	}
	if (Zeny < .@zeny) {
		mes "[Instance Room Personnel]";
		mes "I'm sorry, but you do not have enough zeny to book the room.";
		close;
	}
	Zeny = Zeny-.@zeny;
	set instance, instance_create("BB "+.@roomtype$, .@party_id);
	if (.@instance < 0) {
		mes "[Instance Room Personnel]";
		mes "There was an error when trying to create the instance, please try again!";
		close;
	}
	instance_attachmap("1@brap",.@instance);
	instance_attach(.@instance);
	instance_set_timeout .@timeout,0,.@instance;
	instance_init(.@instance);
	mes "[Instance Room Personnel]";
	mes "Your "+.@roomtype$+" room with the ID "+has_instance("1@brap")+" has been successfully booked!";
	mes "Touch a branch of this tree to enter the room!";
	close;
}

1@brap,26,55,5	script	Musicbox#brap1::mubo	2_M_BARD_ORIENT,{
	mes "[Musicbox]";
	mes "Hi! I can change the background music for you. It'll cost you one coin!";
	mes "Enter a number between 1 and 148! Type in 0 to quit!";
	next;
	do {
		input .@music;
	} while ((.@music < 0) || (.@music > 148));
	if ((.@music == 32) || ((.@music > 132) && (.@music < 139))) {
		mes "[Musicbox]";
		mes "Oh I ... I'm sorry, I can't play this song.";
		close;
	}
	if (.@music == 0) close;
	if (Zeny == 0) {
		mes "["+strcharinfo(0)+"]";
		mes "Damn it, I don't have any change.";
		close;
	}
	mes "[Musicbox]";
	mes "Here you go! Song No."+.@music+" is now playing on "+strcharinfo(3)+"!";
	mes "Have fun~!";
	Zeny = Zeny-1;
	set .@music$,""+.@music;
	if (.@music < 10) set .@music$,"0"+.@music$;
	playbgmall .@music$,strcharinfo(3);
	close;
}

bra_gu1,26,55,5	duplicate(mubo)	Musicbox#brag1	2_M_BARD_ORIENT
bra_gu2,26,55,5	duplicate(mubo)	Musicbox#brag2	2_M_BARD_ORIENT
bra_gu3,26,55,5	duplicate(mubo)	Musicbox#brag3	2_M_BARD_ORIENT

bra_gu1,50,6,0	warp	brapg1_01	1,1,bra_lob,99,93
bra_gu1,6,50,0	warp	brapg1_02	1,1,bra_lob,99,93
bra_gu1,50,93,0	warp	brapg1_03	1,1,bra_lob,99,93
bra_gu1,93,50,0	warp	brapg1_04	1,1,bra_lob,99,93

bra_gu2,50,6,0	warp	brapg2_01	1,1,bra_lob,99,93
bra_gu2,6,50,0	warp	brapg2_02	1,1,bra_lob,99,93
bra_gu2,50,93,0	warp	brapg2_03	1,1,bra_lob,99,93
bra_gu2,93,50,0	warp	brapg2_04	1,1,bra_lob,99,93

bra_gu3,50,6,0	warp	brapg3_01	1,1,bra_lob,99,93
bra_gu3,6,50,0	warp	brapg3_02	1,1,bra_lob,99,93
bra_gu3,50,93,0	warp	brapg3_03	1,1,bra_lob,99,93
bra_gu3,93,50,0	warp	brapg3_04	1,1,bra_lob,99,93

bra_lob,102,95,3	script	Guild Personnel#bra2	4_M_ORIENT02,{
	set .@guid,getcharid(2);
	if ((.@guid != 0) && ((.@guid == $bbguild[0]) || (.@guid == $bbguild[1]) || (.@guid == $bbguild[2]))) {
		if (.@guid == $bbguild[0])
			set .@gnui,1;
		else if (.@guid == $bbguild[1])
			set .@gnui,2;
		else if (.@guid == $bbguild[2])
			set .@gnui,3;
		if (getcharid(0) == getguildmasterid(.@guid)) {
			mes "[Guild Room Personnel]";
			mes "Good day, "+strcharinfo(0)+". You currently booked room no."+.@gnui+" for your guild. Do you want to cancel the reservation? Keep in mind that you will not be refunded for the remaining minutes!";
			next;
			if (select("No:Yes") == 1) {
				mes "[Guild Room Personnel]";
				mes "Alright then, I hope you have a good time!";
				close;
			}
			stopnpctimer "Time Manager#brag"+.@gnui;
			mapannounce "bra_gu"+.@gnui,"Time Manager : Your guild leader canceled the reservation of this room. Warping you out!",bc_map,0x00FF00;
			sleep2 500;
			killmonsterall "bra_gu"+.@gnui;
			set getvariableofnpc(.timeropt,"Time Manager#brag"+.@gnui),0;
			set $bbguild[.@gnui-1],0;
			mapwarp "bra_gu"+.@gnui,"bra_lob",60,100;
			mes "[Guild Room Personnel]";
			mes "The reservation for room no."+.@gnui+" has been canceled! Thank you, and please come again.";
			close;
		} else {
			mes "[Guild Room Personnel]";
			mes "Good day, "+strcharinfo(0)+". Your guild leader booked room no."+.@gnui+" for you. You can enter it by touching a branch of that tree over there.";
			close;
		}
	}
	
	for (set .@i,0; .@i < 3; set .@i,.@i+1) {
		if ($bbguild[.@i] == 0) {
			set .@gnum,.@i;
			break;
		}
		set .@gnum,3;
	}
	if (.@gnum == 3) {
		mes "[Guild Room Personnel]";
		mes "My apologies, but unfortunately, no room is currently available. You have to either wait or book a solo or party room!";
		close;
	} else {
		if (getcharid(0) != getguildmasterid(.@guid)) {
			mes "[Guild Room Personnel]";
			mes "You are not a guild leader. Only leaders can book guild rooms! Please talk to my college over there to book a solo or party room for you!";
			close;
		}
		set .@gnum,.@gnum+1;
		mes "[Guild Room Personnel]";
		mes "Good day to you! I can reserve a Bloody Branch room for your guild. The following rooms are available:";
		mes "Room no.1: "+(($bbguild[0] == 0)?"^00DD00FREE^000000":"^FF0000BOOKED^000000");
		mes "Room no.2: "+(($bbguild[1] == 0)?"^00DD00FREE^000000":"^FF0000BOOKED^000000");
		mes "Room no.3: "+(($bbguild[2] == 0)?"^00DD00FREE^000000":"^FF0000BOOKED^000000");
		next;
		mes "[Guild Room Personnel]";
		mes "I will reserve room no."+.@gnum+" for you, if you want!";
		next;
		switch (select("Eh, not interested, thank you.:10 minutes (^00DD002000z^000000):60 minutes (^0000DD20000z^000000):120 minutes (^DDDD0036000z^000000):180 minutes (^DD000050000z^000000)")) {
		case 1:
			mes "[Guild Room Personnel]";
			mes "As you wish. Come back anytime!";
			close;
			break;
		case 2:
			set getvariableofnpc(.timeropt,"Time Manager#brag"+.@gnum),10;
			set .@zeny,2000;
			break;
		case 3:
			set getvariableofnpc(.timeropt,"Time Manager#brag"+.@gnum),60;
			set .@zeny,20000;
			break;
		case 4:
			set getvariableofnpc(.timeropt,"Time Manager#brag"+.@gnum),120;
			set .@zeny,36000;
			break;
		case 5:
			set getvariableofnpc(.timeropt,"Time Manager#brag"+.@gnum),180;
			set .@zeny,50000;
			break;
		}
		if (Zeny < .@zeny) {
			mes "[Guild Room Personnel]";
			mes "I'm sorry, but you do not have enough zeny to book the room.";
			close;
		}
		Zeny = Zeny-.@zeny;
		set $bbguild[(.@gnum-1)],.@guid;
		initnpctimer "Time Manager#brag"+.@gnum;
		mes "[Guild Room Personnel]";
		mes "The guild room no."+.@gnum+" has been successfully booked for your guild for "+getvariableofnpc(.timeropt,"Time Manager#brag"+.@gnum)+" minutes!";
		mes "Touch a branch of this tree to enter the room!";
	}
	close;
	
OnInit:
	setarray $bbguild[0],0,0,0;
}

bra_gu1,27,56,5	script	Time Manager#brag1	4_M_ORIENT02,{
	set .@curtim, getnpctimer(0);
	npctalk "You have "+(.timeropt-1-.@curtim/60000)+" minute(s) and "+(60 - (.@curtim%60000)/1000)+" second(s) left.";
	end;

Cleanup:
	announce "Time Manager : Countdown! 10 ...",bc_map|bc_npc,0x00FF00;
	sleep 1000;
	for (set .@i,9; .@i > 0; set .@i,.@i-1) {
		announce "Time Manager : "+.@i+" ...",bc_map|bc_npc,0x00FF00;		
		sleep 1000;
	}
	stopnpctimer;
	announce "Time Manager : TIME'S UP! Warping you all out now!",bc_map|bc_npc,0x00FF00;		
	set .timeropt, 0;
	set $bbguild[0],0;
	killmonsterall "bra_gu1";
	mapwarp "bra_gu1","bra_lob",60,100;
	end;

OnTimer300000:
	announce "Time Manager : 5 minutes have passed.",bc_map|bc_npc,0x00FF00;
	end;

OnTimer540000:
	if (.timeropt == 10) announce "Time Manager : 1 minute left until the room disappears!",bc_map|bc_npc,0x00FF00;
	end;
	
OnTimer590000:
	if (.timeropt == 10) goto Cleanup;
	end;

OnTimer1800000:
	announce "Time Manager : 30 minutes have passed.",bc_map|bc_npc,0x00FF00;
	end;

OnTimer3540000:
	if (.timeropt == 60) announce "Time Manager : 1 minute left until the room disappears!",bc_map|bc_npc,0x00FF00;
	end;

OnTimer3590000:
	if (.timeropt == 60) goto Cleanup;
	end;
	
OnTimer5400000:
	announce "Time Manager : 90 minutes have passed.",bc_map|bc_npc,0x00FF00;
	end;

OnTimer7140000:
	if (.timeropt == 120) announce "Time Manager : 1 minute left until the room disappears!",bc_map|bc_npc,0x00FF00;
	end;

OnTimer7190000:
	if (.timeropt == 120) goto Cleanup;
	end;
	
OnTimer9000000:
	announce "Time Manager : 150 minutes have passed.",bc_map|bc_npc,0x00FF00;
	end;

OnTimer10740000:
	announce "1 minute left until the room disappears!",bc_map|bc_npc,0x00FF00;
	end;

OnTimer10790000:
	goto Cleanup;
	end;
}

bra_gu2,27,56,5	script	Time Manager#brag2	4_M_ORIENT02,{
	set .@curtim, getnpctimer(0);
	npctalk "You have "+(.timeropt-1-.@curtim/60000)+" minute(s) and "+(60 - (.@curtim%60000)/1000)+" second(s) left.";
	end;

Cleanup:
	announce "Time Manager : Countdown! 10 ...",bc_map|bc_npc,0x00FF00;
	sleep 1000;
	for (set .@i,9; .@i > 0; set .@i,.@i-1) {
		announce "Time Manager : "+.@i+" ...",bc_map|bc_npc,0x00FF00;		
		sleep 1000;
	}
	stopnpctimer;
	announce "Time Manager : TIME'S UP! Warping you all out now!",bc_map|bc_npc,0x00FF00;		
	set .timeropt, 0;
	set $bbguild[1],0;
	killmonsterall "bra_gu2";
	mapwarp "bra_gu2","bra_lob",60,100;
	end;

OnTimer300000:
	announce "Time Manager : 5 minutes have passed.",bc_map|bc_npc,0x00FF00;
	end;

OnTimer540000:
	if (.timeropt == 10) announce "Time Manager : 1 minute left until the room disappears!",bc_map|bc_npc,0x00FF00;
	end;
	
OnTimer590000:
	if (.timeropt == 10) goto Cleanup;
	end;

OnTimer1800000:
	announce "Time Manager : 30 minutes have passed.",bc_map|bc_npc,0x00FF00;
	end;

OnTimer3540000:
	if (.timeropt == 60) announce "Time Manager : 1 minute left until the room disappears!",bc_map|bc_npc,0x00FF00;
	end;

OnTimer3590000:
	if (.timeropt == 60) goto Cleanup;
	end;
	
OnTimer5400000:
	announce "Time Manager : 90 minutes have passed.",bc_map|bc_npc,0x00FF00;
	end;

OnTimer7140000:
	if (.timeropt == 120) announce "Time Manager : 1 minute left until the room disappears!",bc_map|bc_npc,0x00FF00;
	end;

OnTimer7190000:
	if (.timeropt == 120) goto Cleanup;
	end;
	
OnTimer9000000:
	announce "Time Manager : 150 minutes have passed.",bc_map|bc_npc,0x00FF00;
	end;

OnTimer10740000:
	announce "1 minute left until the room disappears!",bc_map|bc_npc,0x00FF00;
	end;

OnTimer10790000:
	goto Cleanup;
	end;
}

bra_gu3,27,56,5	script	Time Manager#brag3	4_M_ORIENT02,{
	set .@curtim, getnpctimer(0);
	npctalk "You have "+(.timeropt-1-.@curtim/60000)+" minute(s) and "+(60 - (.@curtim%60000)/1000)+" second(s) left.";
	end;

Cleanup:
	announce "Time Manager : Countdown! 10 ...",bc_map|bc_npc,0x00FF00;
	sleep 1000;
	for (set .@i,9; .@i > 0; set .@i,.@i-1) {
		announce "Time Manager : "+.@i+" ...",bc_map|bc_npc,0x00FF00;		
		sleep 1000;
	}
	stopnpctimer;
	announce "Time Manager : TIME'S UP! Warping you all out now!",bc_map|bc_npc,0x00FF00;		
	set .timeropt, 0;
	set $bbguild[2],0;
	killmonsterall "bra_gu3";
	mapwarp "bra_gu3","bra_lob",60,100;
	end;

OnTimer300000:
	announce "Time Manager : 5 minutes have passed.",bc_map|bc_npc,0x00FF00;
	end;

OnTimer540000:
	if (.timeropt == 10) announce "Time Manager : 1 minute left until the room disappears!",bc_map|bc_npc,0x00FF00;
	end;
	
OnTimer590000:
	if (.timeropt == 10) goto Cleanup;
	end;

OnTimer1800000:
	announce "Time Manager : 30 minutes have passed.",bc_map|bc_npc,0x00FF00;
	end;

OnTimer3540000:
	if (.timeropt == 60) announce "Time Manager : 1 minute left until the room disappears!",bc_map|bc_npc,0x00FF00;
	end;

OnTimer3590000:
	if (.timeropt == 60) goto Cleanup;
	end;
	
OnTimer5400000:
	announce "Time Manager : 90 minutes have passed.",bc_map|bc_npc,0x00FF00;
	end;

OnTimer7140000:
	if (.timeropt == 120) announce "Time Manager : 1 minute left until the room disappears!",bc_map|bc_npc,0x00FF00;
	end;

OnTimer7190000:
	if (.timeropt == 120) goto Cleanup;
	end;
	
OnTimer9000000:
	announce "Time Manager : 150 minutes have passed.",bc_map|bc_npc,0x00FF00;
	end;

OnTimer10740000:
	announce "1 minute left until the room disappears!",bc_map|bc_npc,0x00FF00;
	end;

OnTimer10790000:
	goto Cleanup;
	end;
}