viewing paste quests_dewata.txt | Athena

Posted on the
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180
//===== eAthena Script =======================================
//= Dewata Quests Script
//===== By: ==================================================
//= Chilly
//===== Current Version: =====================================
//= 1.0
//===== Compatible With: =====================================
//= Any Athena Version
//===== Description: =========================================
//= Official quests for Dewata
//===== Additional Comments: =================================
//= 1.0 First Release
//============================================================
 
dew_in01,15,49,5        script  Chief of Dewata 540,{
        if (checkweight(1101,2) == 0) {
                mes "^3355FFWait a second!";
                mes "Right now, you're carrying";
                mes "too many things with you.";
                mes "Please come back after";
                mes "using the Kafra Service";
                mes "to store some of your items.^000000";
                close;
        }
        if (dewdungeon < 1) {
                mes "[Chief of Dewata]";
                mes "Hello stranger, have you come to see the volcanic island of Krakatoa?";
                next;
                switch(select("Yes.:Nope.")) {
                case 1:
                        mes "[Chief of Dewata]";
                        mes "First you must do something for me.";
                        next;
                        set dewdungeon,1;
                        mes "[Chief of Dewata]";
                        mes "Bring me ^0000FF15 Cendrawasih Feathers^000000, we need them to make hats for our tribe.";
                        close;
                case 2:
                        mes "[Chief of Dewata]";
                        mes "Then you must leave, foreigners bring trouble.";
                        close;
                }
        }
        else if ((dewdungeon == 1) && (countitem(6405) >= 15)) {
                mes "[Chief of Dewata]";
                mes "You make the chief proud, you may now travel to the volcanic island of Krakatoa.";
                next;
                mes "[Chief of Dewata]";
                mes "Please keep this ^0000FFShining Cendrawasih Feather^000000 with you as proof that you are part of our tribe.";
                next;
                delitem 6405,15;
                getitem 6406,1; // Shining Cendrawasih Feather
                getitem 18520,1; // Jati Crown
                set dewdungeon,2;
                mes "[Chief of Dewata]";
                mes "You may also take one of these hats with you for your fight against the plant monsters outside our village.";
                close;
        }
        else if ((dewdungeon == 1) && (countitem(6405) < 15)) {
                mes "[Chief of Dewata]";
                mes "Where are the ^0000FF15 Cendrawasih Feathers^000000 i asked for?";
                close;
        }
        else if (dewdungeon >= 2) {
                mes "[Chief of Dewata]";
                mes "You may now travel to the volcanic island of Krakatoa.";
                next;
                mes "[Chief of Dewata]";
                mes "Talk to the blacksmith on the field, he may have a weapon for you too.";
                close;
        }
}
 
dew_fild01,127,240,4    script  Blacksmith#dew01        813,{
        if (checkweight(13067,1) == 0) {
                mes "^3355FFWait a second!";
                mes "Right now, you're carrying";
                mes "too many things with you.";
                mes "Please come back after";
                mes "using the Kafra Service";
                mes "to store some of your items.^000000";
                close;
        }
        if (dewdungeon < 2) {
                mes "[Blacksmith]";
                mes "Nice weather we are having today.";
                next;
                mes "[Blacksmith]";
                mes "Don't worry about me, these monsters are no match as long as I have this dagger!";
                close;
        }
        else if (dewdungeon == 2) {
                mes "[Blacksmith]";
                mes "Oh, you want this dagger too?";
                next;
                mes "[Blacksmith]";
                mes "It's annoying for me to make, but i'll do it.";
                next;
                set dewdungeon,3;
                mes "[Blacksmith]";
                mes "Go to the volcanic island and get ^0000FF100 Comodo Leathers^000000 for me, I need to make the Hilt before anything else.";
                close;
        }
        else if ((dewdungeon == 3) && (countitem(6403) >= 100)) {
                mes "[Blacksmith]";
                mes "Wow, you got 100 already.  Let me forge this together for you.";
                next;
                delitem 6403,100;
                getitem 6404,1; // Kris_Hilt
                set dewdungeon,4;
                mes "[Blacksmith]";
                mes "All done!  Now to make the rest of the dagger i'll need ^0000FF100 more Comodo Leathers^000000.  Don't keep me waiting!";
                close;
        }
        else if ((dewdungeon == 3 || dewdungeon == 4) && (countitem(6403) < 100)) {
                mes "[Blacksmith]";
                mes "Where are the ^0000FF100 Comodo Leathers^000000 i asked for?";
                close;
        }
        else if ((dewdungeon == 4) && (countitem(6403) >= 100)) {
                mes "[Blacksmith]";
                mes "Alright, another 100!  I'll have the dagger ready for you in a second.";
                next;
                delitem 6403,100;
                delitem 6404,1;
                getitem 13067,1; // Kris
                set dewdungeon,5;
                mes "[Blacksmith]";
                mes "There you go!  This dagger will heal some of your health when you attack, put it to good use my friend!";
                close;
        }
        else if (dewdungeon >= 5) {
                mes "[Blacksmith]";
                mes "Having fun with my dagger?";
                close;
        }
}
 
dewata,234,64,4 script  Sailor#dew01    540,{
        if (dewdungeon < 2) {
                mes "[Sailor]";
                mes "You no can go to island, need chief permission.";
                close;
        }
        else if (dewdungeon >= 2) {
                mes "[Sailor]";
                mes "Chief say you can go to island, you come?";
                next;
                switch(select("Yes.:Nope.")) {
                case 1:
                        mes "[Sailor]";
                        mes "Ok, you come.";
                        close2;
                        warp "dew_dun01",291,160;
                        end;
                case 2:
                        mes "[Sailor]";
                        mes "Ok, you swim to island.";
                        close;
                }
        }
}
 
dew_dun01,291,164,4     script  Sailor#dew02    540,{
        mes "[Sailor]";
        mes "You go back?";
        next;
        switch(select("Yes.:Nope.")) {
        case 1:
                mes "[Sailor]";
                mes "Ok, you go back.";
                close2;
                warp "dewata",234,60;
                end;
        case 2:
                mes "[Sailor]";
                mes "Ok, you swim to town.";
                close;
        }
}
Viewed 410 times, submitted by unknown.