-   script  PoringEvent2    -1,{
 
OnInit:
    // how many poring each map
    .poring_amount = 5;
    // event last how long ?
    .duration = 30;
    // map list
    setarray .map$,
        "prontera",
        "morocc",
        "payon",
        "aldebaran",
        "geffen";
    .map_size = getarraysize( .map$ );
    .npc_name$ = strnpcinfo(0);
    end;
    
OnClock0030:
OnClock0230:
OnClock0245:
OnClock0430:
OnClock0630:
OnClock0830:
OnClock1030:
OnClock1230:
OnClock1430:
OnClock1630:
OnClock1830:
OnClock2130:
OnClock2330:
if( !.status ){
    .status = 1;
    for( .@i = 0; .@i < .map_size; .@i++ ){
        killmonster .map$[.@i],.npc_name$+"::OnPoringDead";
        monster .map$[.@i],0,0,"Poring",1002,.poring_amount,.npc_name$+"::OnPoringDead";
        monster .map$[.@i],0,0,"Poring",1002,15,"";   // <--- NORMAL PORING
    }
    announce "HAPPY HOUR: Five special Porings and 15 normal Porings have spawned in each Town ("+implode( .map$,"," )+")!",0;
    
    sleep ( .duration * 60000 );
    
    for( .@i = 0; .@i < .map_size; .@i++ )
        killmonster .map$[.@i],.npc_name$+"::OnPoringDead";
    .status = 0;
}
end;
 
// kill poring get reward
OnPoringDead:
    .@count = mobcount( strcharinfo(3),.npc_name$+"::OnPoringDead" );
    announce strcharinfo(0)+" has killed the Poring! "+.@count+" special Porings left in "+strcharinfo(3),(( .@count )? bc_map:bc_all );
    getitem 6153,50;
        dispbottom "Congrats " + strcharinfo(0) + "! You killed a Special Poring!";
    end;
 
}