//===== Hercules Script ======================================
//= Brasilis Town
//===== By: ==================================================
//= L0ne_W0lf
//===== Current Version: =====================================
//= 1.3
//===== Description: =========================================
//= [Official Conversion]
//= Brasilis Town Script
//===== Additional Comments: =================================
//= 1.0 First version. Transportation and Basic NPCs.
//= 1.1 Fixed Zeny not being removed for payment. [Kisuka]
//= 1.2 Updated dialog, added Ice Cream Maker. [L0ne_W0lf]
//= 1.3 Moved Alberta NPC to pre-re/re paths. [Euphy]
//============================================================
 
// Brasilis Transportation
//============================================================
/* Pre-Renewal coordinates: alberta,247,115,3 */
alberta,246,82,3    script  Tripulante#bra2 4W_SAILOR,{
    mes "[Tripulante]";
    mes "Ei, você já ouviu falar de um lugar chamado Brasilis?";
    mes "É uma cidade tropical, que é quente como o deserto, mas também chove. Dizem que é um lugar muito misterioso.";
    next;
    mes "[Tripulante]";
    mes "Recentemente encontrei um novo caminho marítimo para chegar lá facilmente.";
    mes "Por apenas 10.000 zenys podemos viajar de ida e volta! Então você quer ir?";
    next;
    switch(select("Leve-me para Brasilis!:Eu vou ficar aqui.")) {
    case 1:
        if (Zeny > 9999) {
            mes "[Tripulante]";
            mes "Legal~!! Vamos Lá~!";
            Zeny -= 10000;
            close2;
            warp "brasilis",314,60;
            end;
        }
        else {
            mes "[Tripulante]";
            mes "Eu disse 10,000 zenys.";
            close;
        }
    case 2:
        mes "[Tripulante]";
        mes "Bem, volte se você estiver interessado, sempre que quiser poderei levá-lo lá.";
        close;
    }
}
 
brasilis,316,57,3   script  Tripulante#bra1 4W_SAILOR,{
    mes "[Tripulante]";
    mes "Esse navio está indo para trás de Alberta, você quer se juntar a nós?";
    next;
    switch(select("Volte para Alberta.:Ainda Não~.")) {
    case 1:
        mes "[Tripulante]";
        mes "Eu sinto falta de casa.";
        close2;
        if (checkre(0))
            warp "alberta",243,82;
        else
            warp "alberta",244,115;
        end;
    case 2:
        mes "[Tripulante]";
        mes "Ok, fique à vontade. Quando quiser partir avise.";
        close;
    }
}
 
// Generic Brasilis NPCs
//============================================================
brasilis,155,165,3  script  Orientação#bra1   4_BULLETIN_BOARD2,{
    mes ":: Museu de Art ::";
    close;
}
 
brasilis,195,231,3  script  Orientação#bra2   4_BULLETIN_BOARD2,{
    mes ":: Monumento ::";
    close;
}
 
brasilis,240,247,3  script  Orientação#bra3   4_BULLETIN_BOARD2,{
    mes ":: Mercado ::";
    mes " ";
    mes "- Para procurar Poções e Armamento -";
    close;
}
 
brasilis,303,309,3  script  Orientação#bra4   4_BULLETIN_BOARD2,{
    mes ":: Floresta ::";
    mes "";
    mes "- Não é para os fracos de coração -";
    close;
}
 
brasilis,278,137,3  script  Orientação#bra5   4_BULLETIN_BOARD2,{
    mes ":: Hotel de Brasilis ::";
    close;
}
 
brasilis,137,77,5   script  Sorveteiro  4_M_03,{
    mes "[Sorveteiro]";
    mes "Venham~venham~";
    mes "Sorvetes são perfeitos para um dia quente como hoje~";
    mes "E custam apenas ^3355FF100 Zeny^000000~";
    mes "Sorvetes~";
    mes "Pegue o seu sorvete!";
    next;
    switch(select("Me dê um!:Sorvete?:Cancelar.")) {
    case 1:
        mes "[Sorveteiro]";
        mes "Como muitas pessoas procuram por sorvetes você pode encomendar apenas 5 de cada vez.";
        mes "Então quantos você vai querer?";
        next;
        while(1) {
            input .@input; //,1,5;
            if (.@input == 0) {
                mes "[Sorveteiro]";
                mes "Nada?";
                mes "Então saia daqui, eu tenho muitos clientes para atender.";
                close;
            } else if ((.@input < 0) || (.@input > 5)) {
                mes "[Sorveteiro]";
                mes "Uau.";
                mes "Você pediu uma quantidade não permitida.";
                next;
            } else
                break;
        }
        set .@icecream_hap,.@input*100;
        if (Zeny < .@icecream_hap) {
            mes "[Sorveteiro]";
            mes "Você não possui os zenys necessários.";
            mes "São apenas ^3355FF100 Zeny^000000~!";
            close;
        }
        if (!checkweight(536,.@input)) {
            mes "[Sorveteiro]";
            mes "Você parece estar carregando muitas coisas.";
            mes "Reduza um pouco de seu peso antes.";
            close;
        }
        set zeny,zeny-.@icecream_hap;
        getitem 536,.@input; //Sorvete
        close;
    case 2:
        mes "[Sorveteiro]";
        mes "'Sorvetes são...'";
        mes "Espere, você não sabe";
        mes "o que é um sorvete?";
        mes "Como você está conseguindo";
        mes "viver nesse calor?";
        next;
        mes "[Sorveteiro]";
        mes "Isso parece estranho.";
        mes "De qualquer forma, aproveite enquanto os sorvetes estão bons e frios.";
        close;
    case 3:
        mes "[Sorveteiro]";
        mes "Não perca a chance de comer o melhor Sorvete de todo o mundo~!";
        close;
    }
}