viewing paste Unknown #34996 | Text

Posted on the
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154
//===== Hercules Script ===========================================
//= King of Emperium Hill
//===== By: =======================================================
//= AnnieRuru
//===== Current Version: ==========================================
//= 1.1
//===== Compatible With: ==========================================
//= hercules 2015-12-19
//===== Description: ==============================================
//= defends the emperium in the middle of the map until times up
//===== Topic =====================================================
//= http://hercules.ws/board/topic/4495-gvg-king-of-emperium-hill/
//===== Additional Comments: ======================================
//= Finally there is a topic for this !
//=================================================================
// KoE Entrance
prontera,156,171,4  script  The King#KoE    EMPELIUM,{
    mes "[The King]";
    if ( !getcharid(2) ) {
        mes "You must have a guild to participate in the ^FF0000King of Emperium Hill Tournament^000000.";
        next;
        close;
    }
    mes "Hello.";
    mes "Would you like to participate in the ^FF0000King of Emperium Hill Tournament^000000?";
    
    if ( select ( "Yes", "No" ) == 2 ) close;
    if ( !getvariableofnpc( .start, "KoE" ) ) 
    close;
    switch( rand(1,4) ){
    case 1: warp "guild_vs2", 50, 91; end;
    case 2: warp "guild_vs2", 92, 50; end;
    case 3: warp "guild_vs2", 50, 9; end;
    case 4: warp "guild_vs2", 8, 50; end;
    }
}
 
// KoE Exit
guild_vs2,49,56,5   script  Rewarder NPC#KoE    1_M_BARD,{
    mes "[Exit]";
    mes "See ya!!";
    close2;
    warp "Save",0,0;
    if ( getcharid(2) == $koegid )
        getitem 677, 1;
        getitem 7227, 2;
        getitem 31051, 2;
        getitem 14004, 1;
        getitem 14232, 10;
        getitem 31052, 10;
    end;
}
 
// Flags
guild_vs2,64,34,1   script  King of Emperium Hill#1::koe_flag   GUILD_FLAG,{
    if ( !$koegid ) end;
    mes "[King of Emperium Hill]";
    mes "The Current King of Emperium Hill is the [ ^FF0000"+ getguildname($koegid) +"^000000 ] guild.";
    close;
//OnInit: // Uncomment this line to make the emblem stay after @reloadscript
OnRevKoE:
    flagemblem $koegid;
    end;
}
-   script  KoE FAKE_NPC,{
OnInit:
    disablenpc "The King#KoE";
    disablenpc "Rewarder NPC#KoE";
    bindatcmd "koe", strnpcinfo(0)+"::OnCommand", 99,100;
    end;
OnCommand:
    if ( compare( .@atcmd_parameters$, "on" ) ) goto L_Start;
    else if ( compare( .@atcmd_parameters$, "off" ) ) goto L_End;
    else {
        dispbottom "type - '@koe on' to start the event";
        dispbottom "type - '@koe off' to end the event";
    }
    end;
L_Start:
OnClock2230:
OnClock0330:
OnClock0930:
OnClock1530:
OnClock1930:
    if ( .start ) end;
    gvgon "guild_vs2";
    announce "The King of Emperium Hill has begun!", bc_all;
    .start = true;
    enablenpc "The King#KoE";
    enablenpc "The King#KoE2";
    enablenpc "The King#KoE3";
    enablenpc "The King#KoE4";
    enablenpc "The King#KoE5";
    enablenpc "The King#KoE6";
    disablenpc "Rewarder NPC#KoE";
    $koegid = 0;
    donpcevent "::OnRevKoE";
    maprespawnguildid "guild_vs2", $koegid, 3;
    killmonster "guild_vs2", "KoE::OnEmpDead";
    monster "guild_vs2",50,50, "EMPERIUM", EMPELIUM, 1, "KoE::OnEmpDead";
    end;
L_End:
OnClock2300:
OnClock0400:
OnClock1000:
OnClock1600:
OnClock2000:
    gvgoff "guild_vs2";
    announce "The King of Emperium Hill is over. Congratulations to ["+ getguildname($koegid) +"] guild.", bc_all;
    .start = 0;
    enablenpc "Rewarder NPC#KoE";
    warpguild "guild_vs2",49,49,$koegid;
    disablenpc "The King#KoE";
    disablenpc "The King#KoE2";
    disablenpc "The King#KoE3";
    disablenpc "The King#KoE4";
    disablenpc "The King#KoE5";
    disablenpc "The King#KoE6";
    killmonster "guild_vs2", "KoE::OnEmpDead";
    maprespawnguildid "guild_vs2", $koegid, 2; // uncomment this line to kick non-owner off the map when event ends
    end;
OnEmpDead:
    $koegid = getcharid(2);
    announce "The current [ King Of Emperium Hill ] has been conquered by [ "+strcharinfo(0)+" ] of the [ "+ strcharinfo(2) +" ] guild.", bc_all;
    donpcevent "::OnRevKoE";
    maprespawnguildid "guild_vs2", $koegid, 2;
    killmonster "guild_vs2", "KoE::OnEmpDead";
    sleep 500;
    if ( .start )
        monster "guild_vs2",50,50, "EMPERIUM", EMPELIUM, 1, "KoE::OnEmpDead";
    end;
 
}
 
guild_vs2,65,67,3   duplicate(koe_flag) King of Emperium Hill#2 GUILD_FLAG
guild_vs2,34,67,5   duplicate(koe_flag) King of Emperium Hill#3 GUILD_FLAG
guild_vs2,34,32,7   duplicate(koe_flag) King of Emperium Hill#4 GUILD_FLAG
prontera,146,174,5  duplicate(koe_flag) King of Emperium Hill#5 GUILD_FLAG
new_1-1,53,111,0    duplicate(The King#KoE) The King#KoE2   EMPELIUM
gonryun,160,113,0   duplicate(The King#KoE) The King#KoE3   EMPELIUM
louyang,217,48,0    duplicate(The King#KoE) The King#KoE4   EMPELIUM
lighthalzen,158,92,0    duplicate(The King#KoE) The King#KoE5   EMPELIUM
morocc,160,89,0 duplicate(The King#KoE) The King#KoE6   EMPELIUM
 
guild_vs2   mapflag nobranch
guild_vs2   mapflag nomemo
guild_vs2   mapflag nopenalty
guild_vs2   mapflag noreturn
guild_vs2   mapflag nosave  SavePoint
guild_vs2   mapflag noteleport
guild_vs2   mapflag gvg_noparty
guild_vs2   mapflag nowarp
guild_vs2   mapflag nowarpto
guild_vs2   mapflag guildlock
Viewed 936 times, submitted by Guest.