viewing paste Unknown #17684 | Athena

Posted on the
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167
//===== BrAthena Script ======================================
//= Cidade de Brasilis
//===== Por: =================================================
//= L0ne_W0lf
//===== Versão Atual: ========================================
//= 1.4
//===== Descrição: ===========================================
//= [Official Conversion]
//= Brasilis Town Script
//===== Comentários Adicionais: ==============================
//= 1.0 First version. Transportation and Basic NPCs.
//= 1.1 Fixed Zeny not being removed for payment. [Kisuka]
//= 1.2 Updated dialog, added Ice Cream Maker. [L0ne_W0lf]
//= 1.3 Moved Alberta NPC to pre-re/re paths. [Euphy]
//= 1.4 Adicionada Tradução PT-BR. [Mihael]
//============================================================
 
// Teletransporadora
//============================================================
// Pre-Renewal coordenadas: alberta,247,115,3 */
 
alberta,246,82,3        script  Tripulante#bra2 4W_SAILOR,{
        mes "[Tripulante]";
        mes "Ei, você já ouviu falar de um lugar chamado Brasilis?";
        mes "É uma cidade tropical, que é quente como o deserto, mas também chove. Dizem que é um lugar muito misterioso.";
        next;
        mes "[Tripulante]";
        mes "Recentemente encontrei um novo caminho marítimo para chegar lá facilmente.";
        mes "Por apenas 10.000 zenys podemos viajar de ida e volta! Então você quer ir?";
        next;
        switch(select("Leve-me para Brasilis!:Eu vou ficar aqui.")) {
        case 1:
                if (Zeny > 9999) {
                        mes "[Tripulante]";
                        mes "Legal~!! Vamos Lá~!";
                        Zeny -= 10000;
                        close2;
                        warp "brasilis",314,60;
                        end;
                }
                else {
                        mes "[Tripulante]";
                        mes "Eu disse 10,000 zenys.";
                        close;
                }
        case 2:
                mes "[Tripulante]";
                mes "Bem, volte se você estiver interessado, sempre que quiser poderei levá-lo lá.";
                close;
        }
}
 
brasilis,316,57,3       script  Tripulante#bra1 4W_SAILOR,{
        mes "[Tripulante]";
        mes "Esse navio está indo para trás de Alberta, você quer se juntar a nós?";
        next;
        switch(select("Volte para Alberta.:Ainda Não~.")) {
        case 1:
                mes "[Tripulante]";
                mes "Eu sinto falta de casa.";
                close2;
                if (checkre(0))
                        warp "alberta",243,82;
                else
                        warp "alberta",244,115;
                end;
        case 2:
                mes "[Tripulante]";
                mes "Ok, fique à vontade. Quando quiser partir avise.";
                close;
        }
}
 
// Generic Brasilis NPCs
//============================================================
brasilis,155,165,3      script  Orientação#bra1       4_BULLETIN_BOARD2,{
        mes ":: Museu de Art ::";
        close;
}
 
brasilis,195,231,3      script  Orientação#bra2       4_BULLETIN_BOARD2,{
        mes ":: Monumento ::";
        close;
}
 
brasilis,240,247,3      script  Orientação#bra3       4_BULLETIN_BOARD2,{
        mes ":: Mercado ::";
        mes " ";
        mes "- Para procurar Poções e Armamento -";
        close;
}
 
brasilis,303,309,3      script  Orientação#bra4       4_BULLETIN_BOARD2,{
        mes ":: Floresta ::";
        mes "";
        mes "- Não é para os fracos de coração -";
        close;
}
 
brasilis,278,137,3      script  Orientação#bra5       4_BULLETIN_BOARD2,{
        mes ":: Hotel de Brasilis ::";
        close;
}
 
brasilis,137,77,5       script  Sorveteiro      4_M_03,{
        mes "[Sorveteiro]";
        mes "Venham~venham~";
        mes "Sorvetes são perfeitos para um dia quente como hoje~";
        mes "E custam apenas ^3355FF100 Zeny^000000~";
        mes "Sorvetes~";
        mes "Pegue o seu sorvete!";
        next;
        switch(select("Me dê um!:Sorvete?:Cancelar.")) {
        case 1:
                mes "[Sorveteiro]";
                mes "Como muitas pessoas procuram por sorvetes você pode encomendar apenas 5 de cada vez.";
                mes "Então quantos você vai querer?";
                next;
                while(1) {
                        input .@input; //,1,5;
                        if (.@input == 0) {
                                mes "[Sorveteiro]";
                                mes "Nada?";
                                mes "Então saia daqui, eu tenho muitos clientes para atender.";
                                close;
                        } else if ((.@input < 0) || (.@input > 5)) {
                                mes "[Sorveteiro]";
                                mes "Uau.";
                                mes "Você pediu uma quantidade não permitida.";
                                next;
                        } else
                                break;
                }
                set .@icecream_hap,.@input*100;
                if (Zeny < .@icecream_hap) {
                        mes "[Sorveteiro]";
                        mes "Você não possui os zenys necessários.";
                        mes "São apenas ^3355FF100 Zeny^000000~!";
                        close;
                }
                if (!checkweight(536,.@input)) {
                        mes "[Sorveteiro]";
                        mes "Você parece estar carregando muitas coisas.";
                        mes "Reduza um pouco de seu peso antes.";
                        close;
                }
                set zeny,zeny-.@icecream_hap;
                getitem 536,.@input; //Sorvete
                close;
        case 2:
                mes "[Sorveteiro]";
                mes "'Sorvetes são...'";
                mes "Espere, você não sabe";
                mes "o que é um sorvete?";
                mes "Como você está conseguindo";
                mes "viver nesse calor?";
                next;
                mes "[Sorveteiro]";
                mes "Isso parece estranho.";
                mes "De qualquer forma, aproveite enquanto os sorvetes estão bons e frios.";
                close;
        case 3:
                mes "[Sorveteiro]";
                mes "Não perca a chance de comer o melhor Sorvete de todo o mundo~!";
                close;
        }
}
Viewed 447 times, submitted by unknown.