viewing paste Unknown #27650 | Text

Posted on the
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237
-       script  Giant_Settings  -1,{
OnInit:
        set $Giant_Cooldown,28800;      // 冷卻時間
        set $Giant_Timelimit,14400;     // 挑戰時間
        set $Giant_Minlevel,130;                // 最小等級
        set $Giant_Minparty,1;          // 最低人數
        set $Giant_AshID,6000;          // ItemID
        set $Giant_GM,60;                       // Min GM level to control the tower           
        end;
}
 
// = Tower Protection Stone - Register for the memorial dungeon =
//
Jsp,36,51,4     script  警備兵       635,{
        if (BaseLevel <  $Giant_Minlevel ) {
        mes "[警備兵]";      
        mes "為了你的生命安全著想,";
        mes "請先等到LV^ffff00"+$Giant_Minlevel+"^000000後再來挑戰吧。";
        close;
        }
        getpartymember(getcharid(1));
        if(!getcharid(1) || $@partymembercount < $Giant_Minparty){
                mes "[警備兵]";
                mes "請加入一個超過"+$Giant_Minparty+"人的隊伍再來挑戰吧.";
                set Giant_makeparty,1;
                close;
        }
        if(Giant_makeparty){
                mes "[警備兵]";
                mes "你在一支不錯的隊伍裡啊,請問你要做什麼呢";
                set Giant_makeparty,0;
                next;
        }
        mes "[警備兵]";
        mes "如果你有一個已經生成好的副本";
        mes "那你現在就可以進去";
        next;
        if(getpartyleader(getcharid(1),2) == getcharid(0)){
                select("生成寶箱巨鱷副本:進入寶箱巨鱷副本:取消");
        } else {
                select(":進入寶箱巨鱷副本:取消");
        }
        switch(@menu){
        case 1:
                if(instance_id(1)){
                        if(has_instance("1@ma_c") == ""){
                                mes "[警備兵]";
                                mes "你的隊伍已經申請了另一個副本,請先完成,或者放棄";
                                close;
                        }
                        mes "[警備兵]";
                        mes "你的隊伍已經申請過了寶箱巨鱷副本挑戰";
                        mes "請在主界面選擇 ^0000FF進入寶箱巨鱷副本選項^000000 來開始你的挑戰吧。";
                        close;
                }
                if(Giant_Lasttime + $Giant_Cooldown > gettimetick(2) && getgmlevel() < $Giant_GM) {
                        set .@last,Giant_Lasttime + $Giant_Cooldown - gettimetick(2);
                        set .@hours,.@last / 60 / 60;
                        set .@minutes,.@last / 60 % 60;
                        set .@seconds,.@last % 60;
                        mes "[警備兵]";
                        mes "根據生成規則,你現在無法生成寶箱巨鱷副本";
                        mes "你現在還有, "+.@hours+"小時 "+.@minutes+"分鐘 "+.@seconds+"秒才能生成";
                        close;
                }
                mes "[警備兵]";
                mes "^0000FF寶箱巨鱷副本^000000 - 正在準備中";
                mes "當寶箱巨鱷準備完成後,請選擇進入寶箱巨鱷副本開始你的挑戰吧";
                close2;
                set .@instance_id,instance_create("寶箱巨鱷",getcharid(1));
                if(.@instance_id < 0){
                        mes "創建副本失敗";
                        mes "副本系統已經達到系統上限";
                        mes "請通知GM或者管理員";
                        close;
                }
                // > Rev 14006
                instance_attachmap("1@ma_c",.@instance_id);
                instance_set_timeout $Giant_Timelimit,300,.@instance_id;
                instance_init .@instance_id;
                instance_attach .@instance_id;
                set 'Giant_Lasttime,gettimetick(2);
                disablenpc instance_npcname("Giant_Lost_Soul");
                end;
        case 2:
                if(Giant_Lasttime + $Giant_Cooldown > gettimetick(2) && getgmlevel() < $Giant_GM) {
                        set .@last,Giant_Lasttime + $Giant_Cooldown - gettimetick(2);
                        set .@hours,.@last / 60 / 60;
                        set .@minutes,.@last / 60 % 60;
                        set .@seconds,.@last % 60;
                        mes "[警備兵]";
                        mes "根據入場規則,你現在無法入場寶箱巨鱷副本";
                        mes "你現在還有, "+.@hours+"小時 "+.@minutes+"分鐘 "+.@seconds+"秒才能入場";
                        close;
                }
                if(!instance_id(1) || has_instance("1@ma_c") == ""){
                        mes "[警備兵]";
                        mes "寶箱巨鱷副本不存在.";
                        mes "請確定你的隊伍已經申請過寶箱巨鱷副本挑戰,並且你們的挑戰副本並沒有因為長時間沒有人參加而取消";
                        close;
                }
                instance_attach instance_id(1);
                if(Giant_Lasttime + $Giant_Cooldown < gettimetick(2))
                        set Giant_Lasttime,'Giant_Lasttime;
                warp has_instance("1@ma_c"),28,57;
                end;
        case 3:
                close;
        }
OnInit: waitingroom "寶箱巨鱷",0; end;
}
 
//=========================
1@ma_c,1,1,1    script  Giant_Manager   -1,{
        OnAppend1:
                if('Giant_boss==1){
                sleep2 90000;
                areawarp has_instance("1@ma_c"),68,97,115,38,"1@ma_c",32,114;
                areawarp has_instance("1@ma_c"),47,57,117,107,"1@ma_c",32,114;
                areawarp has_instance("1@ma_c"),28,58,42,55,"1@ma_c",32,114;
                donpcevent instance_npcname("Giant_Manager")+"::OnAppend2";
                }
                end;
 
        OnBOSS:
                areamonster "1@ma_c",61,83,115,38,"--ja--",2191,15;
                areamonster "1@ma_c",52,59,117,106,"--ja--",2191,15;
                areamonster "1@ma_c",83,39,85,107,"--ja--",2191,15;
                areamonster "1@ma_c",124,83,65,86,"--ja--",2191,15;
                set 'Giant_boss,1;
                instance_announce .@i,"寶箱巨鱷: 又是想來奪走我寶箱的人嗎?",bc_map,0x66CDAA;
                sleep2 1000;
                instance_announce .@i,"寶箱巨鱷: 不可原諒!!!",bc_map,0x66CDAA;
                sleep2 1000;
                instance_announce .@i,"時空旅人: 英雄們中間沼澤出現了Boss,快上前抓住牠吧!",bc_map,0x11FFFF;
                sleep2 1000;
                areamonster "1@ma_c",94,87,94,87,"寶箱巨鱷(分身)",2538,1,instance_npcname("Giant_Manager")+"::OnBOSS1";
                donpcevent instance_npcname("Giant_Manager")+"::OnAppend1";
                end;
 
        OnAppend2:
                if('Giant_boss==1){
                set 'Giant_Append,2;
                disablenpc instance_npcname("Giant_1");
                sleep2 1000;
                instance_announce .@i,"寶箱巨鱷: 喂喂~你們在箱子裡掙扎看看!",bc_map,0x66CDAA;
                sleep2 1000;
                instance_announce .@i,"時空旅人: 寶箱裏頭一定有牠弱點,冒險者們快找到弱點破壞牠。",bc_map,0x11FFFF;
                areamonster "1@ma_c",28,111,28,111,"寶箱巨鱷的弱點",2333,1,instance_npcname("Giant_Manager")+"::OnAppend3";
                areamonster "1@ma_c",39,111,39,111,"寶箱巨鱷的弱點",2333,1,instance_npcname("Giant_Manager")+"::OnAppend3";
                }
                end;
 
        OnAppend3:
                set 'Giant_Append,'Giant_Append-1;
                if ('Giant_Append ==0 ){
                instance_announce .@i,"寶箱巨鱷: 你怕了嗎?呵呵呵!",bc_map,0x66CDAA;
                sleep2 1000;
                instance_announce .@i,"時空旅人: 傳送點出現了!趕快離開!!。",bc_map,0x11FFFF;
                enablenpc instance_npcname("Giant_1");
                if('Giant_boss==1)
                donpcevent instance_npcname("Giant_Manager")+"::OnAppend1";
                }
                end;
        OnBOSS1:
                sleep2 2000;
                instance_announce .@i,"寶箱巨鱷: 這是...我...必殺的...分身攻擊!",bc_map,0x66CDAA;
                areamonster "1@ma_c",94,87,94,87,"寶箱巨鱷(分身)",2538,1;
                areamonster "1@ma_c",94,87,94,87,"寶箱巨鱷(分身)",2538,1;
                areamonster "1@ma_c",94,87,94,87,"寶箱巨鱷",2319,1,instance_npcname("Giant_Manager")+"::OnBOSS2";
                sleep2 2000;
                instance_announce .@i,"時空旅人: 事情變得更麻煩了!!出現了巨鱷的分身,必須打倒本尊才可以制伏他!",bc_map,0x11FFFF;
                end;
        OnBOSS2:
                set 'Giant_boss,0;
                killmonsterall has_instance("1@ma_c");
                instance_announce .@i,"寶箱巨鱷: 我的...寶箱...",bc_map,0x66CDAA;
                sleep2 2000;
                instance_announce .@i,"時空旅人: 英雄們,巨鱷已被我們制伏了!謝謝你們的幫助!",bc_map,0x11FFFF;
                sleep2 2000;
                enablenpc instance_npcname("Giant_Lost_Soul");
                end;
}
 
// ====================================================================================================
1@ma_c,39,58,5  script  【卡爾斯】警備兵#1      570,{
        mes "[警備兵]";
        mes "要開始挑戰^FF4422寶箱巨鱷^000000了嗎?";
        next;
        switch(select("來吧!:等..等一下!")) {
                case 1:
                        if(getpartyleader(getcharid(1),2) != getcharid(0)){
                        mes "[警備兵]";
                        mes "你不是報名者,";
                        mes "沒辦法開始副本。";
                        close;
                        }
                        mes "[警備兵]";
                        mes "那祝你好運囉!";
                        donpcevent instance_npcname("Giant_Manager")+"::OnBOSS";
                        disablenpc instance_npcname("【卡爾斯】警備兵#1");
                        close;
                case 2:
                        mes "[警備兵]";
                        mes "等你準備好後,再來告訴我";
                        close;
        }
        end;
}
 
// ====================================================================================================
1@ma_c,101,86,5 script  時空旅人#Giant::Giant_Lost_Soul     408,{
        cutin "jpn_anni01",2;
        mes "[時空旅人]";
        mes "恭喜你,完成了寶箱巨鱷副本。";
        next;
        cutin "",255;
        warp "Jsp",48,46;
        announce "恭喜您,完成了寶箱巨鱷副本。",bc_self,0xFFAEB9;
        close;
        end;
}
 
 
1@ma_c,33,117,0 script  Giant_1 45,1,1,{ warp has_instance("1@ma_c"),98,73; end; }
 
// = Mapflags =
// ====================================================================================================
1@ma_c  mapflag nowarp
1@ma_c  mapflag nowarpto
1@ma_c  mapflag noteleport
1@ma_c  mapflag nosave  SavePoint
1@ma_c  mapflag nomemo
1@ma_c  mapflag nobranch
1@ma_c  mapflag noicewall
1@ma_c  mapflag restricted      7
1@ma_c  mapflag monster_noteleport
Viewed 490 times, submitted by unknown.