//===== BrAthena Script ======================================
//= Ilha de Dewata
//===== Por: =================================================
//= Gennosuke Kouga, Muad_Dib
//===== Versão Atual: ========================================
//= 1.4
//===== Descrição: ===========================================
//= [Official Conversion]
//= Dewata Town Script
//===== Comentários Adicionais: ==============================
//= 1.0 First version.
//= 1.1 Standardized. [Euphy]
//= 1.2 Fixed Zeny check. [Joseph]
//= 1.3 Updated to match the official script. [Lemongrass/Euphy]
//= 1.4 Adicionada Tradução PT-BR. [Mihael]
//============================================================
 
// Teleportadora
//============================================================
alberta,212,202,4   script  Sailor de Dewata#alberta    4_M_DEWMAN,{
    mes "[Sailor de Dewata]";
    mes "Você gostaria de visitar a ^8B4513Ilha de Dewata^000000?";
    mes "Com ondas deslumbrantes e vistas encantadoras é um ótimo lugar para relaxar.";
    mes "Mas não será de graça, a taxa de trânsição é de 10.000 Zenys.";
    next;
    switch(select("Leve-me para Dewata!:Desculpe.")) {
    case 1:
        if (Zeny >= 10000) {
            mes "[Sailor de Dewata]";
            mes "^8B4513Dewata^000000 é um lugar bonito e uma ilha muito pacífica.";
            mes "Tenha uma boa viagem~";
            close2;
            Zeny -= 10000;
            warp "dewata",232,53;
            end;
        } else {
            mes "[Sailor de Dewata]";
            mes "Você não tem mesmo idade para isso, criança.";
            mes "Volte quando você tirar sua carteira de maior.";
            close;
        }
    case 2:
        mes "[Sailor de Dewata]";
        mes "Avise-me";
        mes "quando você estiver pronto para viajar~";
        close;
    }
}
 
dewata,229,49,6 script  Sailor de Alberta#dewata    4_M_DEWMAN,{
    mes "[Sailor de Alberta]";
    mes "Você deseja voltar para Alberta?";
    next;
    switch(select("Sim.:Não.")) {
    case 1:
        mes "[Sailor de Alberta]";
        mes "Eu espero que você tenha se divertido";
        mes "na viagem para a ^8B4513Ilha de Dewata^000000.";
        mes "Por favor, volte novamente!";
        close2;
        warp "alberta",210,198;
        end;
    case 2:
        mes "[Sailor de Alberta]";
        mes "Tenha um pouco mais de diversão antes de ir.";
        mes "A ^8B4513Ilha de Dewata^000000 ainda deve ter mais a oferecer.";
        close;
    }
}
 
// Generic Dewata NPCs
//============================================================
dewata,221,237,5    script  Jovem em Dewata#dew-1   4_M_DEWMAN,{
    mes "[Jovem Amante de Frutas]";
    mes "O que há de errado com você? Concerteza você deve estar perdido!";
    next;
    mes "[Jovem Amante de Frutas]";
    mes "Deixe-me que eu conheça um pouco sobre você.";
    next;
    mes "[Jovem Amante de Frutas]";
    mes "Eu posso ser um jovem, mas ninguém sabe mais do que eu sobre o ^777700Fruto da Palmeira^000000. Isso mesmo! O que você quer saber?";
    next;
    switch(select("Sobre o casco...:Sobre a pulpa...:Sobre a semente da fruta...:Não preciso de nada.")) {
    case 1:
        mes "[Jovem Amante de Frutas]";
        mes "Então você quer saber sobre o casco da fruta da palmeira? Deixe-me te explicar.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "Normalmente o casco de frutas de palmeira são utilizadas para se extrair óleo. Oléo de palmeira é um ingrediente útil em muitos pratos.";
        next;
        mes "[Jovem Amante de Frutas]";
        if (dew_drink > 0)
            mes "Hmm... Você já conheceu Memo? Fale com ele e então você entenderá.";
        else
            mes "Se você quer saber como utilizar o óleo de palmeira, encontre Memo no lado norte da ilha de Dewata. Todos os dias, ele faz bebidas tradicionais com Óleo de Palmeira.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "De qualquer forma, nós nos referimos ao óleo que vem do fruto da palmeira como óleo de palmeira ou óleo de coco, é um óleo bem conhecido por sua qualidade.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "Resíduos utilizados na produção de óleo estão sendo secados e utilizados como combustível para se fazer fogo ou serem utilizados na cozinha.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "Ele aquece bem e tem um cheiro agradável, não há como ser melhor do que isso.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "Certo!! Isso é tudo sobre o casco, leva muito tempo para detalhar todos os efeitos úteis da casca da fruta de palmeira.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "Não posso te ensinar tudo. Não me leve a mal!";
        close;
    case 2:
        mes "[Jovem Amante de Frutas]";
        mes "Então o que você quer saber sobre a poupa do Fruto de Palmeira? Deixe-me te explicar.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "O Fruto de Palmeira possui 2 camadas. A de fora é muito dura, e a de dentro é macia...";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "Hmm... Sim! A polpa do Fruto da Palmeira é um pouco mais dura que a casca de noz, isso deve ser devido a água que existe em seu interior.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "No interior da casca, a cerca de 300cc de água que é utilizada para matar a sede das pessoas, já que a ilha de Dewata possui um clima muito quente.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "E depois de de bebermos a água nós não jogamos a poupa fora!!";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "Nós também podemos fazer uma garrafa de água com ela! Como eu disse, o fruto tem uma casca dura o bastante para se fazer uma garrafa de água muito resistente.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "O fruto também é ótimo para se fazer carvão. O carvão feito de frutos da palmeira é bem utilizado no fogo devido a sua longa duração e qualidade.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "As pessoas amam cozinhar frutos do mar e frango com esse carvão..";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "O carvão é ardente e ainda possui o cheiro da palmeira.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "Certo!! Isso é tudo sobre a polpa, leva muito tempo para detalhar todos os efeitos úteis da casca da fruta de palmeira.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "Não posso te ensinar tudo. Não me leve a mal!";
        close;
    case 3:
        mes "[Jovem Amante de Frutas]";
        mes "Então você quer saber sobre a semente que existe dentro do fruto? Deixe-me te explicar.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "A semente que existe dentro do interior do fruto é usada como um digestivo natural.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "Não há muito a dizer sobre a semente..";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "Mesmo assim, pode-se dizer que tudo do fruto é reaproveitável.";
        next;
        mes "[Jovem Amante de Frutas]";
        mes "Você não acha??";
        close;
    case 4:
        mes "[Jovem Amante de Frutas]";
        mes "Arrgg! Está faltando falta de interesse em você!";
        close;
    }
}
 
dewata,114,243,6    script  Jovem em Dewata#dew 4_M_DEWMAN,1,1,{
    if (checkweight(1201,1) == 0 || MaxWeight - Weight < 500) {
        mes "[Jovem em Dewata]";
        mes "Por que você está carregando tantas coisas? Não está pesado?";
        close;
    }
    if (countitem(11534)) {
        mes "[Jovem em Dewata]";
        mes "Hã~!! É o Suco de Palmeira?";
        mes "Você pode me dá-lo? Eu acabei de";
        mes "acordar, e minha garganta está seca!";
        next;
        switch(select("Dar:Não dar")) {
        case 1:
            mes "[Jovem em Dewata]";
            mes "Sério? Para mim?? Eu vou te presentear... Obrigado... Hehe~";
            delitem 11534,1; //Coco_Juice
            getrandgroupitem(IG_GiftBox),1;
            close;
        case 2:
            mes "[Jovem em Dewata]";
            mes "Está bem~ Certo...";
            close;
        }
    }
    mes "[Jovem em Dewata]";
    mes "Ah~ Sede~ Você pode me dar um pouco de suco de";
    mes "Palmeira?~";
    close;
OnTouch:
    if (!countitem(11534)) {
        mes "[Jovem em Dewata]";
        mes "Ah~ Sede~ Você pode me dar um pouco de suco de";
        mes "Palmeira?~";
        emotion e_an;
        next;
        emotion e_an;
        next;
        emotion e_an;
        next;
        emotion e_an;
        close;
    }
    end;
}
 
dewata,159,81,4 script  Turista#dew-1   4_M_SITDOWN,{
    mes "[Nasolo]";
    mes "Uau, oceano puro, praia limpa...";
    mes "Seria bacana se minha namorada estivesse aqui...";
    next;
    mes "[Nasolo]";
    mes "Mas ela não está...";
    emotion e_sob;
    next;
    mes "[Nasolo]";
    mes "Quando será que minha princesa virá?";
    emotion e_sigh;
    close;
}
 
dewata,146,109,5    script  Sr. Dwi Oblo#dew    4_COOK,{
    if (checkweight(11532,1) == 0 || checkweight(11533,1) == 0 || MaxWeight - Weight < 500) {
        mes "[Sr. Dwi Oblo]";
        mes "Você veio experimentar o meu prato? É sempre bom comer de estômago vazio.";
        close;
    }
    mes "[Sr. Dwi Oblo]";
    mes "Bem-vindo a ilha Dewata.";
    mes "Gostaria que você se comportasse";
    mes "como um nobre viajante, não como";
    mes "aqueles rebeldes adolescentes...";
    next;
    switch(select("Sobre comidas de Dewata:Cardápio de hoje?:Não preciso de nada.")) {
    case 1:
        mes "[Sr. Dwi Oblo]";
        mes "Precisa de informações sobre nossas comidas? Bem... Não tenho muito a dizer, mas fique à vontade para ouvir, se quiser.";
        next;
        mes "[Sr. Dwi Oblo]";
        mes "Sim... Essa seria uma boa informação.";
        next;
        mes "[Sr. Dwi Oblo]";
        mes "Primeiro, os pratos de Dewata têm nomes especiais baseados em cada tipo de comida.";
        next;
        mes "[Sr. Dwi Oblo]";
        mes "Se o nome do prato tiver 'Goreng' nele, são comidas misturadas ou fritas.";
        next;
        mes "[Sr. Dwi Oblo]";
        mes "Se for um tipo de 'Bakar', então são comidas grelhadas.";
        next;
        mes "[Sr. Dwi Oblo]";
        mes "E se for 'Saté', você estará comendo um prato de espeto.";
        next;
        mes "[Sr. Dwi Oblo]";
        mes "Segundo, temos pratos com nomes de ingredientes básicos.";
        next;
        mes "[Sr. Dwi Oblo]";
        mes "Na ilha de Dewata, chamamos arroz de Nasi, macarrão de Mie, pão de Roti, frango de Ayam, peixe de Ikan e milho de Jagung.";
        next;
        mes "[Sr. Dwi Oblo]";
        mes "Então, se o arroz é frito, o chamamos de 'Nasi Goreng' e macarrão frito é 'Mie Goreng.";
        next;
        mes "[Sr. Dwi Oblo]";
        mes "Bem... Isso é o bastante para saborear nossas comidas em Dewata!! Se estiver com fome, temos nosso cardápio especial por apenas ^0000ff5000^000000 Zeny.";
        close;
    case 2:
        mes "[Sr. Dwi Oblo]";
        mes "Nós temos 2 'Nasi Goreng' e 'Saté' no Cardápio, qual você quer?";
        next;
        switch(select("Nasi Goreng:Satay")) {
        case 1:
            mes "[Sr. Dwi Oblo]";
            mes "Nós temos 2 'Nasi Goreng' e 'Saté' no Cardápio, qual você quer?.";
            set .@food,11532;
            break;
        case 2:
            mes "[Sr. Dwi Oblo]";
            mes "Esse é o Nasi Goreng frito com meu molho especial e ovo frito em cima, custa apenas ^0000ff5000^000000 Zeny .";
            set .@food,11533;
            break;
        }
        next;
        if(select("Experimentar:Ir embora") == 2) {
                mes "[Sr. Dwi Oblo]";
                mes "É uma pena você não experimentar";
                mes "esse prato, ele é ótimo...";
                close;
            }
            mes "[Sr. Dwi Oblo]";
            if(Zeny < 5000) {
                mes "Onde está o dinheiro? Hã!! Aqui não";
                mes "tem comida de graça! Certo?";
                close;
            }
            mes "Aqui está o seu "+getitemname(.@item)+", você não vai se arrepender.";
            set Zeny,Zeny - 5000;
            getitem .@item,1;
            close;
        case 3:
            mes "Está falando sério? Isso nem é engraçado.";
    }
    close;
}
 
dewata,147,107,6    script  Rustam#dew  4_M_03,{
    mes "[Rustam]";
    mes "Ah... tem um gosto ótimo...";
    mes "é muito convidativo!";
    emotion e_sob;
    next;
    mes "[Rustam]";
    mes "Mestre, Mais um, por favor~";
    emotion e_no1;
    emotion e_ok,0,"Sr. Dwi Oblo#dew";
    next;
    mes "[Rustam]";
    mes "Você tem de experimentar isso! Todas as comidas daqui são ótimas~";
    close;
}
 
dewata,154,107,4    script  Turista de passagem#dew 4_M_04,{
    mes "[Turista de passagem]";
    mes "Uau...";
    mes "Quantos ele já comeu?";
    emotion e_hmm;
    next;
    mes "[Turista de passagem]";
    mes "Ele deve ser um comilão, não um apreciador...";
    next;
    mes "[Turista de passagem]";
    mes "Você já esteve em Prontera? Acho que já o vi em algum lugar..";
    close;
}
 
dewata,95,203,6 script  Guia Turístico#dew 4_M_DEWMAN,{
    mes "[Guide]";
    mes "O templo de Borobudur venera O Buda";
    mes "da ilha Dewata do século IX.";
    emotion e_swt2;
    next;
    mes "[Guide]";
    mes "Esse templo foi feito com 6 plataformas quadradas, 3 plataformas redondas e 2672 painéis simbólicos da salvação, além de 504 estátuas de Budas.";
    emotion e_swt2;
    next;
    mes "[Guide]";
    mes "O alojamento do meio está localizado no centro da plataforma superior, cercada por 72 estátuas de Budas.";
    emotion e_swt2;
    next;
    mes "[Guide]";
    mes "E o templo de Borobudur ainda é famoso e procurado para peregrinação por muitos monges que veneram o Buda. Ele tem grande parte nos negócios de propaganda de turismo da ilha Dewata.";
    emotion e_swt2;
    next;
    mes "[Guide]";
    mes "Isso é tudo sobre o templo de Borobudur, mas alguém tem perguntas?";
    mes "Se não podemos prosseguir para o próximo ponto.";
    close;
}
 
dewata,97,207,4 script  Waldo#dew1  1_F_SIGNZISK,{
    mes "[Waldo]";
    mes "Oh... Porcaria... Escolhi o guia";
    mes "turístico errado...";
    next;
    mes "[Waldo]";
    mes "Isso é tão chato... Quem é aquela";
    mes "pessoa? Por que prolongar isso?";
    emotion e_spin;
    next;
    mes "[Waldo]";
    mes "Com certeza... Preciso ter mais sorte com pacotes de compra...";
    emotion e_sigh;
    close;
}
 
dewata,100,206,4    script  Turista#dew2    1_M_ORIENT01,{
    mes "[Turista]";
    mes "Ei... Vamos para lá... Depressa,";
    mes "enquanto o guia está explicando.";
    next;
    mes "[Turista]";
    mes "Ora, vamos... Não parece que esse";
    mes "guia vai terminar tão cedo.";
    close;
}
 
dewata,101,206,4    script  Turista#dew3    4_F_01,{
    mes "[Turista]";
    mes "Não vamos nos perder sem o guia?";
    next;
    mes "[Turista]";
    mes "Nós já nos perdemos na última vez...";
    close;
}
 
dewata,99,203,4 script  Turista#dew4    4_M_SAGE_C,{
    mes "[Turista]";
    mes "Oh, isso é muito interessante. Um";
    mes "templo venerando o Buda...";
    emotion e_ok;
    next;
    mes "[Turista]";
    mes "Mas, eu não entendi direito essa";
    mes "parte que você estava nos contando.";
    next;
    mes "[Turista]";
    mes "E... Aqui... O que há de errado com";
    mes "essa parte?";
    close;
}
 
dewata,67,186,8 script  Monge#dew1  4_M_BUDDHIST,{
    mes "[Monge]";
    mes "Eu sou um Monge, dedico meus dias ao estudo religioso.";
    next;
    mes "[Monge]";
    mes "Acabo de voltar de uma peregrinação do templo Borobudur junto com meus companheiros Monges...";
    next;
    mes "[Monge]";
    mes "O Templo de Borobudur possui muitos peregrinos que o visitam, já que esse é um dos poucos templos que se dedicam inteiramente a venerar o Grande Buda.";
    close;
}
 
dewata,65,188,8 script  Monge#dew2  4_M_BUDDHIST,{
    mes "[Monge]";
    mes "Borobudur é um dos poucos templos que se dedicam inteiramente a venerar o Grande Buda.";
    next;
    mes "[Monge]";
    mes "Eu não compreendo por que poucos templos seguem o nosso caminho...";
    close;
}
 
dewata,63,190,8 script  Monge#dew3  4_M_BUDDHIST,{
    mes "[Monge]";
    mes "Você é um Turista? Se quiser você pode fazer uma doação em um dos templos.";
    next;
    mes "[Monge]";
    mes "Nosso grande Buda irá realizar seu desejo..";
    close;
}
 
dewata,62,192,8 script  Monge#dew4  4_M_BUDDHIST,{
    mes "[Monge]";
    mes "Nosso grande Buda é o rei entre as almas e o líder de todos os deuses.";
    next;
    mes "[Monge]";
    mes "As tribos de Dewata acreditam em Buda, o estranho é que todas descrevem seu Buda de uma forma diferente.";
    next;
    mes "[Monge]";
    mes "Eu não sei o motivo exato disso. Talvez seja porque existem muitas tribos em Dewata com características diferentes.";
    close;
}
 
dewata,89,191,6 script  Pequeno Templo#dew1 CLEAR_NPC,{
    mes "Este é um pequeno templo. Onde muitas pessoas fazem seus pedidos.";
    next;
    switch(select("Fazer uma doação.:Fazer um pedido.:Ignorar.")) {
    case 1:
        mes "As doações podem ser feitas entre:";
        mes "^FF00001,000 ~ 100,000 Zeny^000000";
        mes "Quanto você deseja doar?";
        next;
        input .@input,0,100000;
        if (.@input < 1000) {
            mes "- Cancelado. -";
            close;
        } else if (.@input <= 50000)
            set .@good_luck, rand(1,10000);
        else
            set .@good_luck, rand(1,5000);
        if (.@input > Zeny) {
            mes "- Você não possui Zenys suficiente. -";
            close;
        }
        mes "O que você deseja pedir?";
        next;
        input(.@wish$);
 
        setarray .@wishes$[0],
            "Poder","Força", //1
            "Aceleração","Velocidade","Rapidez","Agilidade", //2
            "Mãos Hábeis","Destreza", //4
            "Saúde","Boa Condição Fisíca","Vitalidade", //8
            "Sabedoria","Cérebo","Estudo","Inteligência","1º Lugar", //16
            "Sorte","Riqueza","Itens","Obter itens","Béns","Loteria", //32
            "Nível Máximo","Nível","Nv", //64
            "Amor","Namorada","Namorado"; //128
        setarray .@index[0],
            1,1,2,2,2,2,4,4,8,8,8,16,16,16,16,16,32,32,32,32,32,32,64,64,64,128,128,128;
            
        if (.@good_luck == 7 || .@good_luck == 77 || .@good_luck == 777 || .@good_luck == 7777)
            set .@bonus,1;
        for(set .@i,0; .@i<getarraysize(.@wishes$); set .@i,.@i+1) {
            if (compare(.@wish$,.@wishes$[.@i])) {
                set .@stat, .@stat | .@index[.@i];
                break;
            }
        }
 
        mes "Você fez um pedido de ^0000FF" + .@wish$ + "^000000 para o pequeno templo.";
        next;
        callsub L_Wish;
        set Zeny, Zeny - .@input;
        if (.@stat & 1 && .@bonus)
            consumeitem 12043; //Str_Dish03
        else if (.@stat & 2 && .@bonus)
            consumeitem 12058; //Agi_Dish03
        else if (.@stat & 4 && .@bonus)
            consumeitem 12063; //Dex_Dish03
        else if (.@stat & 8 && .@bonus)
            consumeitem 12053; //Vit_Dish03
        else if (.@stat & 16 && .@bonus)
            consumeitem 12048; //Int_Dish03
        else if (.@stat & 32 && .@bonus)
            consumeitem 12068; //Luk_Dish03
        else if (.@stat & 64) {
            specialeffect2 EF_ANGEL;
            mes "- Uma entidade celestial te abençoou. -";
            next;
        } else if (.@stat & 128) {
            mes "- O templo te envolve com uma aura amorosa. -";
            if ((Sex == 0 && compare(.@wish$,.@wishes$[26])) || (Sex == 1 && compare(.@wish$,.@wishes$[27])))
                specialeffect2 EF_LIGHTSPHERE;
            next;
        }
        mes "Parece que o desejo se tornará realidade.";
        close;
    case 2:
        mes "O que você deseja?";
        next;
        input .@wish$;
        mes "Você fez um pedido de ^0000FF" + .@wish$ + "^000000 para o pequeno templo.";
        next;
        callsub L_Wish;
        mes "Parece que o desejo se tornará realidade.";
        close;
    case 3:
        close;
    }
 
L_Wish:
    mes "Uma misteriosa energia surge do templo.";
    specialeffect EF_FLASHER,AREA,"Pequeno Templo#dew1";
    specialeffect EF_FLASHER,AREA,"Pequeno Templo#dew2";
    specialeffect EF_FLASHER,AREA,"Pequeno Templo#dew3";
    specialeffect EF_FLASHER,AREA,"Pequeno Templo#dew4";
    next;
    mes "Você recebeu a benção do templo.";
    specialeffect2 EF_BLESSING;
    next;
    return;
}
dewata,89,212,6 duplicate(Pequeno Templo#dew1)  Pequeno Templo#dew2 CLEAR_NPC
dewata,68,212,6 duplicate(Pequeno Templo#dew1)  Pequeno Templo#dew3 CLEAR_NPC
dewata,68,191,6 duplicate(Pequeno Templo#dew1)  Pequeno Templo#dew4 CLEAR_NPC
 
dewata,75,122,6 script  Monge Calmo#dewt1   4_M_BUDDHIST,{
    mes "[Monge Calmo]";
    mes "Você é um estrangeiro. O que o traz a esse local tranquilo?";
    next;
    switch(select("Estou passeando.:Nenhum motivo.")) {
    case 1:
        mes "[Monge Calmo]";
        mes "Ah, você é um turista. Esse é um '^0000FFPagode^000000' usado para venerar o grande Buda. Por favor, não interrompa os rituais.";
        close;
    case 2:
        mes "[Monge Calmo]";
        mes "Bom dia para você...";
        close;
    }
}
 
dewata,69,101,6 script  Monge budista#dewt2 4_M_BUDDHIST,{
    mes "[Monge budista]";
    mes "Temos uma torre de veneração ao Buda aqui. Cada templo tem uma dessas torres, poucas pessoas passam por aqui além de nós, monges.";
    next;
    switch(select("Entendi...:Explique sobre o Buda:Ah, ok.")) {
    case 1:
        mes "[Monge budista]";
        mes "Você deve sentir o nosso grande Buda!";
        close;
    case 2:
        mes "[Monge budista]";
        mes "O Buda é o deus do mito de Dewata ele é o rei das almas e o líder de todos os Deuses.";
        next;
        mes "[Monge budista]";
        mes "O Buda é o guardião das almas e muitas vezes descrito na dança tradicional como um lutador contra antigas almas inimigas.";
        next;
        mes "[Monge budista]";
        mes "Em Dewata, nós acreditamos que há muitos deuses protegendo cada local da ilha, a terra e as flores das tribos,";
        next;
        mes "[Monge budista]";
        mes "então, nós temos descrições diferentes para o Buda, geralmente descrito como urso, tigre, dragão serpente e leão";
        next;
        mes "[Monge budista]";
        mes "O Buda Leão é um dos Barões famosos venerados em Dewata.";
        next;
        mes "[Monge budista]";
        mes "Espero que essa tenha sido uma boa explicação para você. Avise-me se quiser saber mais alguma coisa.";
        close;
    case 3:
        mes "[Monge budista]";
        mes "Bom dia para você...";
        close;
    }
}
 
dewata,71,79,6  script  Monge#dewt3 4_M_BUDDHIST,{
    mes "[Monge]";
    mes "Essa torre foi construída à beira de um penhasco de praia, você pode rezar com a brisa fresca do oceano.";
    next;
    mes "[Monge]";
    mes "Venha, você pode sentir o grande Buda com a brisa fresca do oceano.";
    close;
}
 
dewata,211,272,4    script  Sr. Jiawang#dew 4_M_DEWOLDMAN,2,3,{
OnTouch:
    mes "[Sr. Jiawang]";
    mes "Ultimamente, temos muitos casais em lua-de-mel, aqui.";
    next;
    mes "[Sr. Jiawang]";
    mes "Deve ser pelas belas paisagens, certo?";
    next;
    mes "[Sr. Jiawang]";
    mes "Sou feliz com o meu negócio. Espero que todos os casais venham aqui para a sua lua-de-mel.";
    next;
    mes "[Sr. Jiawang]";
    mes "Ah! Você deve trazer a sua pessoa amada para a lua-de-mel em Dewata.";
    mes "Vou lhe dar um bom preço-";
    close;
}
 
dewata,245,244,4    script  Sr. Dingwan#dew 4_M_DEWMAN,2,3,{
OnTouch:
    mes "[Sr. Dingwan]";
    mes "Argg~ Isso está me aborrecendo, de verdade!";
    emotion e_an;
    next;
    mes "[Sr. Dingwan]";
    mes "Como mais e mais casais chegam a nossa pensão, todos os dias?";
    next;
    mes "[Sr. Dingwan]";
    mes "E por que eles têm de falar todas aquelas coisas melosas? O que é aquilo?";
    next;
    mes "[Sr. Dingwan]";
    mes "Qual é, tenham um pouco de respeito por quem trabalha aqui...";
    close;
}
 
dewata,233,263,8    script  Doce Casal de Casados#1 4_M_ROGUE,2,3,{
OnTouch:
    mes "[Doce Marido]";
    mes "Você é a coisa mais linda do mundo, Bebê~";
    emotion e_kis;
    next;
    mes "[Doce Esposa]";
    mes "Sério? Eu sou mesmo linda? Eu te amo, docinho~";
    emotion e_kis2,0,"Doce Casal de Casados#dew2";
    next;
    mes "[Doce Casal de Casados]";
    mes "Hahahahahahahahahahahahahahahahahahahahahahahahahahahahahahahahahahahaha";
    mes "Hohohohohohohohohohohohohohohohohohohohohohohohohohohohohohohohohohohoho";
    emotion e_heh;
    emotion e_heh,0,"Doce Casal de Casados#dew2";
    next;
    mes "Vamos, agora. Vamos em frente.";
    close;
}
 
dewata,234,263,8    script  Doce Casal de Casados#2 4_F_JOB_HUNTER,2,3,{
OnTouch:
    mes "[Doce Esposa]";
    mes "Bebê~ Você sabe que flor é essa~?";
    emotion e_what;
    next;
    mes "[Doce Marido]";
    mes "Hum? Eu não sei. Mas ela é muito linda.";
    next;
    mes "[Doce Esposa]";
    mes "Bebê~ Quem é mais bonita, eu ou a flor?";
    emotion e_what;
    next;
    mes "[Doce Marido]";
    mes "Não importa o quão bonita seja a flor, você sempre será mais linda~";
    emotion e_kis,0,"Doce Casal de Casados#dew1";
    next;
    mes "[Doce Esposa]";
    mes "Sério? Eu sou mesmo linda? Eu te amo, docinho~";
    emotion e_kis2;
    next;
    mes "[Doce Casal de Casados]";
    mes "Hahahahahahahahahahahahahahahahahahahahahahahahahahahahahahahahahahahaha";
    mes "Hohohohohohohohohohohohohohohohohohohohohohohohohohohohohohohohohohohoho";
    emotion e_heh,0,"Doce Casal de Casados#dew1";
    emotion e_heh;
    next;
    mes "Vamos, agora. Vamos em frente.";
    close;
}
 
dewata,279,213,4    script  Josho#dew-2 4_M_LIEMAN,2,3,{
OnTouch:
    mes "[Josho]";
    mes "Uau~ Isso é muito confortável~";
    next;
    mes "[Josho]";
    mes "Quero ter um desses.";
    next;
    mes "[Josho]";
    mes "Você tem de se deitar ao meu lado.";
    mes "Não quero sair daqui.";
    next;
    mes "[Josho]";
    mes "É por isso que estou aqui há quase uma semana. Hahahaha~";
    emotion e_heh;
    close;
}
 
dewata,269,208,4    script  Diwangi#dew 4_M_DEWBOY,2,3,{
OnTouch:
    mes "[Diwangi]";
    mes "Ei "+((Sex)?"irmão":"irmã")+", olhe só aquele homem!";
    next;
    mes "[Diwangi]";
    mes "Ele está deitado lá, há uma semana, sem fazer nada...";
    next;
    mes "[Diwangi]";
    mes "Quem é esse homem?";
    emotion e_what;
    next;
    mes "[Diwangi]";
    mes "Não quero ser como aquele homem quando eu crescer.";
    close;
}
 
dewata,227,129,4    script  Sarr#dew    4_M_DEWBOY,2,3,{
OnTouch:
    mes "[Sarr]";
    mes "Esconde-esconde! Vou encontrar.";
    mes "você!";
    next;
    mes "[Sarr]";
    mes "Um~";
    next;
    mes "[Sarr]";
    mes "Um, dois~";
    next;
    mes "[Sarr]";
    mes "Um, dois, três~";
    next;
    mes "[Sarr]";
    mes "... ... ... ...";
    next;
    mes "[Sarr]";
    mes "Noventa e nove, cem!!! Agora, lá vou eu~";
    close;
}
 
dewata,239,140,4    script  Siyak#dew   4_M_DEWGIRL,2,3,{
OnTouch:
    mes "[Siyak]";
    mes "Ei, venha, mexa-se. Ele vai me encontrar~~";
    next;
    mes "[Sarr]";
    mes "Encontrei Siyak!! Saia, saiam!!";
    emotion e_gg,0,"Sarr#dew";
    emotion e_omg;
    emotion e_gg,0,"Sipo#dew";
    emotion e_omg,1;
    next;
    mes "[Siyak]";
    mes "Arrgg!! Isso é tudo culpa sua~!!";
    emotion e_an;
    close;
}
 
dewata,193,145,4    script  Sipo#dew    4_M_DEWBOY,2,3,{
OnTouch:
    mes "[Sipo]";
    mes "Sarr não vai me encontrar aqui certo?";
    next;
    mes "[Sarr]";
    mes "Encontrei Siyak!! Saia, saiam!!";
    emotion e_gg,0,"Sarr#dew";
    emotion e_omg,0,"Siyak#dew";
    emotion e_gg;
    emotion e_omg,1;
    next;
    mes "[Sipo]";
    mes "Hehe. Agora é a vez de Siyak. Vou continuar me escondendo aqui.";
    close;
}
 
dewata,228,177,4    script  Majya#dew   4_M_DEWBOY,2,3,{
OnTouch:
    mes "[Majya]";
    mes "Eu só estava brincando de esconde-esconde com meus amigos...";
    next;
    mes "[Majya]";
    mes "Só estava parado aqui... Faz três horas e eles ainda não me encontraram......";
    emotion e_hmm;
    next;
    mes "[Majya]";
    mes "O que devo fazer? Sair? Não quero que seja minha vez de procurar...";
    close;
}
 
dewata,278,100,4    script  Criança Perdida#dew    4_F_KID2,2,3,{
OnTouch:
    mes "[Criança Perdida]";
    mes "BuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuá~";
    emotion e_sob;
    emotion e_swt2;
    next;
    mes "["+strcharinfo(0)+"]";
    mes "Ei...";
    next;
    mes "[Criança Perdida]";
    mes "BuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuáBuá~";
    emotion e_sob;
    next;
    mes "[Criança Perdida]";
    mes "Mamãe~ Papai~ Onde estão vocês~ Buá~";
    emotion e_sob;
    emotion e_swt2;
    next;
    mes "["+strcharinfo(0)+"]";
    mes "... ... ...";
    emotion e_dots,1;
    close;
}
 
dewata,249,87,4 script  Mãe#dew    4W_F_01,2,3,{
OnTouch:
    mes "[Mãe]";
    mes "Ukki~ Ukki~ Aonde ela foi?";
    emotion e_wah;
    next;
    mes "[Mãe]";
    mes "Eu não posso deixá-la um segundo...";
    next;
    mes "[Mãe]";
    mes "Ukki~";
    emotion e_wah;
    close;
}
 
dewata,251,85,6 script  Pai#dew 4W_M_01,2,3,{
OnTouch:
    mes "[Pai]";
    mes "Querida, Ukki sumiu de novo?";
    emotion e_what;
    next;
    mes "[Pai]";
    mes "Arrgg... Não posso ir a lugar algum com ela... Quantas vezes isso já aconteceu?";
    emotion e_swt2;
    next;
    mes "[Daddy]";
    mes "Deixe-me ver... Uma vez em Louyang, uma vez em Amatsu, uma vez em Moscovia, uma vez em Brasilis e uma";
    mes "vez em Ayothaya...";
    emotion e_swt2;
    next;
    mes "[Daddy]";
    mes "O quê!! Já foram 7 vezes incluindo a vez em Dewata... 7 vezes!!!!!!";
    emotion e_otl;
    close;
}
 
dewata,278,281,4    script  Vovô Jwang 4_M_DEWOLDMAN,{
    mes "[Vovô Jwang]";
    mes "Hoje, vou pedir para a minha senhora";
    mes "fazer um ^006300Nasi Goreng^000000 para mim.";
    next;
    mes "[Vovô Jwang]";
    mes "O ^006300Nasi Goreng^000000 da minha esposa é";
    mes "sempre muito especial!";
    next;
    mes "[Vovô Jwang]";
    mes "Ele me faz amar minha mulher, ainda mais.";
    mes "É mais do que você pode imaginar!";
    emotion e_lv;
    close;
}
 
dewata,280,277,4    script  Vovó Karing    4_M_DEWOLDWOMAN,{
    mes "[Vovó Karing]";
    mes "Você deveria saber, pela minha aparência";
    mes "que havia muitos rapazes interessados";
    mes "em sair comigo quando eu era jovem e bonita.";
    emotion e_swt2;
    next;
    mes "[Vovó Karing]";
    mes "Depois, encontrei o homem certo";
    mes "e me casei.";
    mes "Perguntei o que ele mais gostava";
    mes "em mim e ele disse que foi o";
    mes "^006300Nasi Goreng^000000 que eu fiz";
    mes "para ele.";
    next;
    mes "[Vovó Karing]";
    mes "E desde então, ele só me pede para";
    mes "fazer ^006300Nasi Goreng^000000 no jantar";
    mes "há 40 anos";
    mes "e ele ainda não enjoou.";
    next;
    mes "[Vovó Karing]";
    mes "Sempre penso que minha maior";
    mes "sorte é envelhecer ao lado do homem";
    mes "que ama a minha comida.";
    emotion e_lv;
    close;
}
 
dewata,165,103,6    script  Aventureiro Semangatt#dew   4_M_DEWOLDMAN,{
    mes "[Aventureiro Semangatt]";
    mes "Também viajei pelo mundo";
    mes "quando eu era jovem como você.";
    mes "^FF0000Macaco, Siba,";
    mes "Águia, Serpente^000000,";
    mes "todos que conheci são bons amigos";
    mes "durante a viagem.";
    next;
    mes "[Aventureiro Semangatt]";
    mes "Eu ainda tenho uma paixão por";
    mes "aventuras e viagens";
    mes "Mas, não posso abandonar";
    mes "minha querida mulher e";
    mes "meus netos.";
    mes "Huh Huh Huh.";
    next;
    mes "[Aventureiro Semangatt]";
    mes "Você também vai ter algo";
    mes "ou alguém muito precioso";
    mes "em seu coração um dia.";
    close;
}
 
dewata,139,114,6    script  Esposa do Aventureiro#dew   4_M_DEWOLDWOMAN,{
    mes "[Esposa do Aventureiro]";
    mes "Onde está o meu velho marido de novo?";
    mes "Você...";
    mes "Viu meu marido por aqui?";
    next;
    switch(select("Acho que o vi ali...:Não, não vi..")) {
    case 1:
        mes "[Esposa do Aventureiro]";
        mes "Ele fugiu quando";
        mes "eu estava procurando por ele.";
        mes "Ele deve estar em algum lugar, enganando";
        mes "algum viajante, agora.";
        next;
        mes "[Esposa do Aventureiro]";
        mes "Peço desculpas";
        mes "em nome de meu marido.";
        mes "Por favor, não acredite em";
        mes "histórias como aquela";
        mes "que ele diz ter encontrado um";
        mes "^FF0000macaco cruel^000000 ou";
        mes "lutar com um ^FF0000siba^000000.";
        mes "[Esposa do Aventureiro]";
        mes "Ele viveu aqui";
        mes "a vida toda.";
        mes "Porém, ele sempre encontra viajantes";
        mes "e os engana com suas histórias.";
        close;
    case 2:
        mes "[Esposa do Aventureiro]";
        mes "Por favor me avise";
        mes "se o vir em algum lugar.";
        close;
    }
}
 
dewata,181,88,6 script  Jovem de Dewata#dew-2   4_M_DEWMAN,{
    mes "[Jovem de Dewata]";
    mes "A praia de ^8C4210Dewata^000000 não é";
    mes "muito bonita?";
    mes "Aquelas crianças brincando";
    mes "pela praia, sempre";
    mes "me lembram da minha juventude.";
    next;
    mes "[Jovem de Dewata]";
    mes "De noite, é ótimo";
    mes "ter fogos de artifício na praia.";
    mes "Com a brisa do oceano, o barulho das ondas,";
    mes "e luzes dos fogos de artifício,";
    mes "será uma noite maravilhosa!";
    close;
}
 
dewata,179,204,4    script  Jovenzinha#dew  4_M_DEWWOMAN,{
    mes "[Jovenzinha]";
    mes "Quando você estiver fora da cidade";
    mes "e encontrar um ^FF0000Tigre, Macaco ou Porco^000000,";
    mes "tente evitá-los.";
    next;
    select("O que você quer dizer?");
    mes "[Jovenzinha]";
    mes "Eu nunca vi,";
    mes "mas, diz a lenda que há um";
    mes "monstro cruel chamado ^FF0000Leak^000000";
    mes "que tem a forma de um animal";
    mes "e mata as pessoas.";
    next;
    mes "[Jovenzinha]";
    mes "Sabe como é o Mundo de hoje em dia...";
    mes "É sempre bom tomar cuidado";
    mes "mesmo que seja uma lenda urbana.";
    //emotion ET_SCRATCH; //TODO
    close;
}
 
dewata,280,236,4    script  Ex-viajante#dew 4_F_JOB_BLACKSMITH,{
    mes "[Ex-viajante]";
    mes "Eu não nasci em Dewata";
    mes "na verdade.";
    mes "Mas, enquanto viajava";
    mes "encontrei este local...";
    mes "E decidi";
    mes "morar neste lugar lindo...";
    next;
    mes "[Ex-viajante]";
    mes "Sou feliz";
    mes "vivendo aqui e";
    mes "apreciando todas essas belas paisagens.";
    mes "É um sonho que se realizou.";
    next;
    mes "[Ex-viajante]";
    mes "Que tal você também se mudar";
    mes "para cá?";
    close;
}
 
dewata,204,230,6    script  Mulher de dieta#dew 4_M_DEWWOMAN,{
    if (countitem(11533) == 0) {
        mes "[Mulher de dieta]";
        mes "Ah, que fome!";
        mes "Eu deveria estar de regime.";
        mes "Por que ainda tenho fome?";
        next;
        mes "[Mulher de dieta]";
        mes "Não fale muito comigo!";
        mes "Quero muito o ^006400Saté^000000 grelhado";
        mes "muito mesmo~!!!!!";
        close;
    }
    mes "[Mulher de dieta]";
    mes "Esse ^006400Saté^000000";
    mes "que parece delicioso, é para mim?";
    next;
    switch(select("Sim, quer experimentar?:Não é meu!")) {
    case 1:
        delitem 11533,1; // Saté
        mes "[Mulher de dieta]";
        mes "Muito obrigada!";
        mes "Estava com tanta fome!!!";
        mes "Esse ^006300Saté^000000,";
        mes "está muito gostoso!";
        next;
        getitem 11533,1; // Saté
        mes "[Mulher de dieta]";
        mes "Ah... Pensando bem,";
        mes "Acho que estou gorda demais...";
        mes "Eu deveria estar de regime.";
        mes "Desculpe, vou lhe devolver o ^006300Saté^000000.";
        emotion e_sob;
        close;
    case 2:
        mes "[Mulher de dieta]";
        mes "Arrgg.. Você é tão mesquinho.";
        mes "Eu vou continuar de regime.";
        mes "Pessoas gordas como eu";
        mes "não merecem essa comida maravilhosa.";
        emotion e_pif;
        close;
    }
}
 
dewata,117,156,6    script  Jovem sonhador#dew  4_M_DEWBOY,{
    mes "[Jovem sonhador]";
    mes "Minha avó disse";
    mes "que, uma vez, um pássaro chamado ^FF0000Garuda^000000";
    mes "voou por esta cidade.";
    mes "E, depois, tivemos uma grande colheita";
    mes "e todos ficaram felizes.";
    next;
    mes "[Jovem sonhador]";
    mes "Quero ver esse pássaro";
    mes "voar pela nossa cidade de novo!";
    mes "Então minha mãe, meu pai";
    mes "e meus avós";
    mes "viveriam todos felizes e unidos.";
    mes "Você não acha?";
    close;
}
 
dewata,144,216,4    script  Jovem decidido#dew  4_M_DEWBOY,{
    mes "[Jovem decidido]";
    mes "Meus pais costumavam dizer:";
    next;
    mes "- ^006300Filho^000000 -";
    mes "- ^006300Você deve estudar muito^000000 -";
    mes "- ^006300e ser feliz.^000000 -";
    mes "- ^006300Viver uma vida tranquila^000000 -";
    mes "- ^006300e segura.^000000 -";
    mes "- ^006300Aquela montanha^000000 -";
    mes "- ^006300estará lá para sempre.^000000 -";
    next;
    mes "[Jovem decidido]";
    mes "Não é incrível o que meus pais diziam?";
    mes "Vou viver como eles mandaram";
    mes "e vou me tornar uma ótima pessoa.";
    mes "E vou ajudar todo o povo da nossa cidade";
    mes "a viver feliz para sempre!";
    close;
}
 
dewata,127,248,6    script  Criança Persistente#dew    4_M_DEWGIRL,{
    mes "[Criança Persistente]";
    mes "Minha família faz";
    mes "vinho tradicional em Dewata.";
    mes "Também quero beber,";
    mes "meu pai diz que sou muito nova.";
    mes "Ele disse que poderei beber";
    mes "se eu dormir mais ^FF0000100 dias^000000.";
    next;
    mes "[Criança Persistente]";
    mes "Todos os adultos adoram beber";
    mes "o vinho do meu pai.";
    mes "Quero tanto beber o vinho.";
    mes "Mas, o que devo fazer?";
    mes "Esqueci quantas ^FF0000noites^000000";
    emotion e_sob;
    close;
}
 
dew_fild01,101,259,6    script  Guardião da Tribo Jaty 4_M_DEWZATIMAN,{
    mes "[Guardião da Tribo Jaty]";
    mes "Bem-vindo a tribo ^FF0000Jaty^000000.";
    mes "Nossa tribo reverencia a força e a bravura.";
    mes "Desejamos-lhe segurança e tranquilidade enquanto estiver entre nós.";
    close;
}
 
dew_fild01,106,306,4    script  Guerreiro da Tribo Jaty 4_M_DEWZATIMAN,{
    mes "[Guerreiro da Tribo Jaty]";
    mes "Eu quero me tornar o melhor";
    mes "assim como ninguém foi.";
    next;
    mes "[Guerreiro da Tribo Jaty]";
    mes "Estou aprendendo habilidades de caça";
    mes "durante esses dias. E eu estou ficando";
    mes "melhor e melhor a cada dia!";
    next;
    mes "[Guerreiro da Tribo Jaty]";
    mes "Eu não vou parar até que eu me torne um verdadeiro guerreiro!";
    close;
}