//===== Hercules Script ======================================
//= Euphy's Quest Shop
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.6a
//===== Compatible With: =====================================
//= Hercules
//===== Description: =========================================
//= A dynamic quest shop based on Lunar's, with easier config.
//= Includes support for multiple shops & cashpoints.
//= Item Preview script by ToastOfDoom.
//===== Additional Comments: =================================
//= 1.0 Initial script.
//= 1.2 Added category support.
//= 1.3 More options and fixes.
//= 1.4 Added debug settings.
//= 1.5 Replaced categories with shop IDs.
//= 1.6 Added support for purchasing stackables.
//= 1.6a Added support for previewing costumes and robes.
//============================================================
 
 
// Shop NPCs -- supplying no argument displays entire menu.
//    callfunc "qshop"{,<shop ID>{,<shop ID>{,...}}};
//============================================================
aretnorp,217,191,5    script    Trader#1    582,{ callfunc "qshop"; }
 
 
 
 
// Script Core
//============================================================
-    script    quest_shop    -1,{ 
function Add; function Chk; function Slot; function A_An;
OnInit:
    freeloop(1);
 
 
// -----------------------------------------------------------
//  Basic shop settings.
// -----------------------------------------------------------
 
 
    set .Announce,1;    // Announce quest completion? (1: yes / 0: no)
    set .ShowSlot,1;    // Show item slots? (2: all equipment / 1: if slots > 0 / 0: never)
    set .ShowID,1;      // Show item IDs? (1: yes / 0: no)
    set .ShowZeny,0;    // Show Zeny cost, if any? (1: yes / 0: no)
    set .MaxStack,100;    // Max number of quest items purchased at one time.
 
 
// -----------------------------------------------------------
//  Points variable -- optional quest requirement.
//    setarray .Points$[0],"<variable name>","<display name>";
// -----------------------------------------------------------
 
 
    setarray .Points$[0],"#CASHPOINTS","Cash Points";
 
 
// -----------------------------------------------------------
//  Shop IDs -- to add shops, copy dummy data at bottom of file.
//    setarray .Shops$[1],"<Shop 1>","<Shop 2>"{,...};
// -----------------------------------------------------------
 
 
    setarray .Shops$[1],"Upgraded Sealed Cards","Collection of Hats","Godly Items";
 
 
// -----------------------------------------------------------
//  Quest items -- do NOT use a reward item more than once!
//    Add(<shop ID>,<reward ID>,<reward amount>,
//        <Zeny cost>,<point cost>,
//        <required item ID>,<required item amount>{,...});
// -----------------------------------------------------------
 
 
 
 
    Add(1,4236,1,0,0,7615,500,4495,1);
    Add(1,4425,1,0,0,7615,500,4536,1);
    Add(1,4145,1,0,0,7615,500,4486,1);
    Add(1,4168,1,0,0,7615,500,4488,1);
    Add(1,4386,1,0,0,7615,500,7227,700);
    Add(1,4134,1,0,0,7615,500,4483,1);
    Add(1,4137,1,0,0,7615,500,4496,1);
    Add(1,4123,1,0,0,7615,500,4504,1);
    Add(1,4352,1,0,0,7615,500,4482,1);
    Add(1,4330,1,0,0,7615,500,4544,1);
    Add(1,4441,1,0,0,7615,500,4539,1);
    Add(1,4408,1,0,0,7615,500,4485,1);
    Add(1,4324,1,0,0,7615,500,4543,1);
    Add(1,4363,1,0,0,7615,500,4501,1);
    Add(1,4365,1,0,0,7615,500,4541,1);
    Add(1,4430,1,0,0,7615,500,4487,1);
    Add(1,4403,1,0,0,7615,500,4480,1);
    Add(1,4419,1,0,0,7615,500,4481,1);
    Add(1,4376,1,0,0,7615,500,4498,1);
    Add(1,4276,1,0,0,7615,500,4540,1);
    Add(1,4361,1,0,0,7615,500,4502,1);
    Add(1,4132,1,0,0,7615,500,4484,1);
    Add(1,4131,1,0,0,7615,500,4490,1);
    Add(1,4143,1,0,0,7615,500,4492,1);
    Add(1,4135,1,0,0,7615,500,4500,1);
    Add(1,4148,1,0,0,7615,500,4489,1);
    Add(1,4121,1,0,0,7615,500,4537,1);
    Add(1,4263,1,0,0,7615,500,4499,1);
    Add(1,4367,1,0,0,7615,500,4491,1);
    Add(1,4318,1,0,0,7615,500,4497,1);
    Add(1,4302,1,0,0,7615,500,4493,1);
    Add(1,4305,1,0,0,7615,500,4494,1);
    Add(1,4374,1,0,0,7615,500,4503,1);
    Add(1,4372,1,0,0,7615,500,4538,1);
    Add(1,4359,1,0,0,7615,500,7227,1500);
    Add(1,4169,1,0,0,7615,500,7227,700);
    Add(1,4047,1,0,0,7615,500,7227,700);
    Add(1,4146,1,0,0,7615,500,7227,700);
    Add(1,4147,1,0,0,7615,500,7227,1000);
 
 
    Add(2,20343,1,0,0,20150,50,20151,50,20168,10);
    Add(2,20342,1,0,0,20152,50,20153,50,20168,10);
    Add(2,20341,1,0,0,20154,50,20155,50,20168,10);    
    Add(2,20335,1,0,0,20156,50,20157,50,20168,10);
    Add(2,20332,1,0,0,20158,50,20159,50,20168,10);
    Add(2,20324,1,0,0,20160,50,20161,50,20168,10);
    Add(2,20323,1,0,0,20161,50,20162,50,20168,10);
    Add(2,20317,1,0,0,20163,50,20164,50,20168,10);
    Add(2,20315,1,0,0,20165,50,20166,50,20168,10);
    Add(2,20314,1,0,0,20150,50,20151,50,20168,10);
    Add(2,20313,1,0,0,20152,50,20153,50,20168,10);
    Add(2,20306,1,0,0,20154,50,20155,50,20168,10);    
    Add(2,20302,1,0,0,20156,50,20157,50,20168,20);
    Add(2,20292,1,0,0,20158,50,20159,50,20168,10);
    Add(2,20284,1,0,0,20160,50,20161,50,20168,10);
    Add(2,20282,1,0,0,20161,50,20162,50,20168,10);
    Add(2,20280,1,0,0,20163,50,20164,50,20168,10);
    Add(2,20187,1,0,0,20165,50,20166,50,20168,20);
    Add(2,20274,1,0,0,20150,50,20151,50,20168,10);
    Add(2,20270,1,0,0,20152,50,20153,50,20168,10);
    Add(2,20269,1,0,0,20154,50,20155,50,20168,10);    
    Add(2,20264,1,0,0,20156,50,20157,50,20168,10);
    Add(2,20253,1,0,0,20158,50,20159,50,20168,10);
    Add(2,20250,1,0,0,20160,50,20161,50,20168,10);
    Add(2,20246,1,0,0,20161,50,20162,50,20168,10);
    Add(2,20242,1,0,0,20163,50,20164,50,20168,10);
    Add(2,20240,1,0,0,20165,50,20166,50,20168,10);
    Add(2,20238,1,0,0,20150,50,20151,50,20168,10);
    Add(2,20237,1,0,0,20152,50,20153,50,20168,10);
    Add(2,20235,1,0,0,20154,50,20155,50,20168,10);    
    Add(2,20236,1,0,0,20156,50,20157,50,20168,10);
    Add(2,20234,1,0,0,20158,50,20159,50,20168,10);
    Add(2,20227,1,0,0,20160,50,20161,50,20168,10);
    Add(2,20226,1,0,0,20161,50,20162,50,20168,10);
    Add(2,20206,1,0,0,20163,50,20164,50,20168,10);
    Add(2,20204,1,0,0,20165,50,20166,50,20168,10);
    Add(2,20203,1,0,0,20150,50,20151,50,20168,10);
    Add(2,20202,1,0,0,20152,50,20153,50,20168,10);
    Add(2,20197,1,0,0,20154,50,20155,50,20168,10);    
    Add(2,20195,1,0,0,20156,50,20157,50,20168,10);
    Add(2,20194,1,0,0,20158,50,20159,50,20168,10);
    Add(2,20192,1,0,0,20160,50,20161,50,20168,10);
    Add(2,20217,1,0,0,20161,50,20162,50,20168,20);
 
 
    Add(3,2410,1,0,0,7079,5,7086,4,7076,3,7087,3,7083,3,969,20,985,10,2405,1);
    Add(3,2629,1,0,0,7058,1,969,20,984,10,726,10,2627,1);
    Add(3,7058,1,0,0,7080,4,7081,5,7082,4,7084,3,7085,3);
    Add(3,2630,1,0,0,7073,4,7077,4,7092,3,7090,3,7088,3,724,5,969,20,726,2,727,10,722,3,2603,1);
    Add(3,1530,1,0,0,7074,2,7075,4,7078,5,7091,5,7089,5,985,5,969,40,984,20,1522,1);
 
 
 
 
 
 
 
 
 
 
 
 
 
 
// -----------------------------------------------------------
 
 
    freeloop(0);
    set .menu$,"";
    for(set .@i,1; .@i<=getarraysize(.Shops$); set .@i,.@i+1) {
        set .menu$, .menu$+.Shops$[.@i]+":";
        npcshopdelitem "qshop"+.@i,909;
    }
    end;
 
 
OnMenu:
    set .@size, getarraysize(@i);
    if (!.@size) set .@i, select(.menu$);
    else if (.@size == 1) set .@i, @i[0];
    else {
        for(set .@j,0; .@j<.@size; set .@j,.@j+1)
            set .@menu$, .@menu$+.Shops$[@i[.@j]]+":";
        set .@i, @i[select(.@menu$)-1];
    }
    deletearray @i[0],getarraysize(@i);
    if (.Shops$[.@i] == "") {
        message strcharinfo(0),"An error has occurred.";
        end;
    }
    dispbottom "Select one item at a time.";
    callshop "qshop"+.@i,1;
    npcshopattach "qshop"+.@i;
    end;
 
 
OnBuyItem:
    // .@q[] : RewardID, BoughtAmt, RewardAmt, BaseAmt, ReqZeny, ReqPts, { ReqItem, ReqAmt, ... }
    setarray .@q[0],@bought_nameid[0],((@bought_quantity[0] > .MaxStack)?.MaxStack:@bought_quantity[0]);
    copyarray .@q[3],getd(".q_"+.@q[0]+"[0]"),getarraysize(getd(".q_"+.@q[0]));
    set .@q[2],.@q[1]*.@q[3];
    if (!.@q[2] || .@q[2] > 30000) {
        message strcharinfo(0),"You can't purchase that many "+getitemname(.@q[0])+".";
        end;
    }
    mes "[Quest Shop]";
    mes "Reward: ^0055FF"+((.@q[2] > 1)?.@q[2]+"x ":"")+Slot(.@q[0])+"^000000";
    mes "Requirements:";
    if (.@q[4]) mes " > "+Chk(Zeny,.@q[4]*.@q[1])+(.@q[4]*.@q[1])+" Zeny^000000";
    if (.@q[5]) mes " > "+Chk(getd(.Points$[0]),.@q[5]*.@q[1])+(.@q[5]*.@q[1])+" "+.Points$[1]+" ("+getd(.Points$[0])+"/"+(.@q[5]*.@q[1])+")^000000";
    if (.@q[6]) for(set .@i,6; .@i<getarraysize(.@q); set .@i,.@i+2)
        mes " > "+Chk(countitem(.@q[.@i]),.@q[.@i+1]*.@q[1])+((.ShowID)?"{"+.@q[.@i]+"} ":"")+Slot(.@q[.@i])+" ("+countitem(.@q[.@i])+"/"+(.@q[.@i+1]*.@q[1])+")^000000";
    next;
    setarray @qe[1], getiteminfo(.@q[0],5), getiteminfo(.@q[0],11);
    if (@qe[2] > 0 && ((@qe[1] & 1) || (@qe[1] & 256) || (@qe[1] & 512) || (@qe[1] & 1024) || (@qe[1] & 2048) || (@qe[1] & 4096) || (@qe[1] & 4) || (@qe[1] & 8192)))
        set .@preview,1;
    addtimer 1000, strnpcinfo(0)+"::OnEnd";
    while(1) {
        switch(select(" ~ Purchase ^0055FF"+getitemname(.@q[0])+"^000000:"+((.@preview && !@qe[7])?" ~ Preview...":"")+": ~ ^777777Cancel^000000")) {
        case 1:
            if (@qe[0]) { 
                mes "[Quest Shop]";
                mes "You're missing one or more quest requirements.";
                close;
            }
            if (!checkweight(.@q[0],.@q[2])) {
                mes "[Quest Shop]";
                mes "^FF0000You need "+(((.@q[2]*getiteminfo(.@q[0],6))+Weight-MaxWeight)/10)+" additional weight capacity to complete this trade.^000000";
                close;
            }
            if (.@q[4]) set Zeny, Zeny-(.@q[4]*.@q[1]);
            if (.@q[5]) setd .Points$[0], getd(.Points$[0])-(.@q[5]*.@q[1]);
            if (.@q[6]) for(set .@i,6; .@i<getarraysize(.@q); set .@i,.@i+2)
                delitem .@q[.@i],.@q[.@i+1]*.@q[1];
            getitem .@q[0],.@q[2];
            if (.Announce) announce strcharinfo(0)+" has created "+((.@q[2] > 1)?.@q[2]+"x "+getitemname(.@q[0]):A_An(getitemname(.@q[0])))+"!",0;
            specialeffect2 EF_FLOWERLEAF;
            close;
        case 2:
            setarray @qe[3], getlook(LOOK_HEAD_BOTTOM), getlook(LOOK_HEAD_TOP), getlook(LOOK_HEAD_MID), getlook(LOOK_ROBE), 1;
            if ((@qe[1] & 1) || (@qe[1] & 4096)) changelook LOOK_HEAD_BOTTOM, @qe[2];
            else if ((@qe[1] & 256) || (@qe[1] & 1024)) changelook LOOK_HEAD_TOP, @qe[2];
            else if ((@qe[1] & 512) || (@qe[1] & 2048)) changelook LOOK_HEAD_MID, @qe[2];
            else if ((@qe[1] & 4) || (@qe[1] & 8192)) changelook LOOK_ROBE, @qe[2];
            break;
        case 3:
            close;
        }
    }
 
 
OnEnd:
    if (@qe[7]) {
        changelook LOOK_HEAD_BOTTOM, @qe[3];
        changelook LOOK_HEAD_TOP, @qe[4];
        changelook LOOK_HEAD_MID, @qe[5];
        changelook LOOK_ROBE, @qe[6];
    }
    deletearray @qe[0],8;
    end;
 
 
function Add {
    if (getitemname(getarg(1)) == "null") {
        debugmes "Quest reward #"+getarg(1)+" invalid (skipped).";
        return;
    }
    setarray .@j[0],getarg(2),getarg(3),getarg(4);
    for(set .@i,5; .@i<getargcount(); set .@i,.@i+2) {
        if (getitemname(getarg(.@i)) == "null") {
            debugmes "Quest requirement #"+getarg(.@i)+" invalid (skipped).";
            return;
        } else
            setarray .@j[.@i-2],getarg(.@i),getarg(.@i+1);
    }
    copyarray getd(".q_"+getarg(1)+"[0]"),.@j[0],getarraysize(.@j);
    npcshopadditem "qshop"+getarg(0),getarg(1),((.ShowZeny)?getarg(3):0);
    return;
}
 
 
function Chk {
    if (getarg(0) < getarg(1)) {
        set @qe[0],1;
        return "^FF0000";
    } else
        return "^00FF00";
}
 
 
function Slot {
    set .@s$,getitemname(getarg(0));
    switch(.ShowSlot) {
        case 1: if (!getitemslots(getarg(0))) return .@s$;
        case 2: if (getiteminfo(getarg(0),2) == 4 || getiteminfo(getarg(0),2) == 5) return .@s$+" ["+getitemslots(getarg(0))+"]";
        default: return .@s$;
    }
}
 
 
function A_An {
    setarray .@A$[0],"a","e","i","o","u";
    set .@B$, "_"+getarg(0);
    for(set .@i,0; .@i<5; set .@i,.@i+1)
        if (compare(.@B$,"_"+.@A$[.@i])) return "an "+getarg(0);
    return "a "+getarg(0);
}
}
 
 
function    script    qshop    {
    deletearray @i[0],getarraysize(@i);
    for(set .@i,0; .@i<getargcount(); set .@i,.@i+1)
        set @i[.@i],getarg(.@i);
    doevent "quest_shop::OnMenu";
    end;
}
 
 
 
 
// Dummy shop data -- copy as needed.
//============================================================
-    shop    qshop1    -1,909:-1
-    shop    qshop2    -1,909:-1
-    shop    qshop3    -1,909:-1